dev-cpp/cpptrace: New package needed by games-engine/odamex

Signed-off-by: James Le Cuirot <chewi@gentoo.org>

dev-cpp/cpptrace/Manifest

@@ -0,0 +1 @@
+DIST cpptrace-1.0.4.tar.gz 494169 BLAKE2B 297bd5680527c01c43c5cbc17efd6dc1e898eb9f708dbc7b8ee714a7dd42283652cca45c66d293f83fdd0c87a1ba743ee1482c077a2804f88b7566e53b3d998e SHA512 e88edddbcdd423d49ed3adb02cf70580ee3a56065db4d81ca69d3f9f6d9b64ac27734842ca3b6d8ff45a548c25900a88f979e39d777af422a153e586d26ac5b5

dev-cpp/cpptrace/cpptrace-1.0.4.ebuild

@@ -0,0 +1,43 @@
+# Copyright 2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Simple, portable, and self-contained stacktrace library for C++11 and newer"
+HOMEPAGE="https://github.com/jeremy-rifkin/cpptrace"
+SRC_URI="https://github.com/jeremy-rifkin/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	app-arch/zstd:=
+	dev-libs/libdwarf:=
+"
+DEPEND="
+	${RDEPEND}
+	test? ( dev-cpp/gtest )
+"
+
+src_prepare() {
+	default
+
+	# Unused CMake files with compatibility issues.
+	rm -v test/*/CMakeLists.txt || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCPPTRACE_BUILD_TESTING=$(usex test)
+		-DCPPTRACE_USE_EXTERNAL_GTEST=yes
+		-DCPPTRACE_USE_EXTERNAL_LIBDWARF=yes
+		-DCPPTRACE_USE_EXTERNAL_ZSTD=yes
+	)
+	cmake_src_configure
+}

dev-cpp/cpptrace/metadata.xml

@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>games@gentoo.org</email>
+		<name>Gentoo Games Project</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">jeremy-rifkin/cpptrace</remote-id>
+	</upstream>
+</pkgmetadata>