dev-python/pyro: Bump version to 4.47

dev-python/pyro/Manifest

@@ -3,3 +3,4 @@ DIST Pyro4-4.25.tar.gz 295993 SHA256 ac2b0123badcb76c63eb716fcd95e0ee4021d345b5d
 DIST Pyro4-4.39.tar.gz 496566 SHA256 39c6ca7f86b0f0bebfeada687a5a8b99f66470a52b0f815195ae63c683266f24 SHA512 ac303401abe997b7ce0914a804538dcee9195bbe3fe1d07cf18be0592cbb4dbd161413e8d7a696a8dc1e29ff64fe98877ea1fa9811d9961340441cf414f31d98 WHIRLPOOL fc4377552f9e5f5666671d909b7c071095933625baea891535c976f735dab8f3d1b5b3f0132be2fcf9a003024d874a88ddd092b127127c0376807a1d2894d393
 DIST Pyro4-4.40.tar.gz 501340 SHA256 00423d3710f60b2da146075a59e17bfa837f556ed2c8acafe05bc209dcaac3e9 SHA512 43ee1b0dd3e700d9fed16c5fceda30074dc6cd3cbd466efe911711eb81f1c4bce1967bed06225922e45812e04e36c49cd42d24c0edca1845159d1035326896e7 WHIRLPOOL fdc5f2f405a217db0840218201b1d943ef5828513cc606135dbe5dd7fb723dedec78ad25e8ea6cc2ca0a3e4b374eb8a73fe7db0dae6dcac117c0af9d0e757def
 DIST Pyro4-4.41.tar.gz 502294 SHA256 3af4749140e9d4032632277ac19e7fd4761856d2df0f0643c574d1e7174a9703 SHA512 01c3f16448b39cd7a83c845eec86013315ee183a3e50c6caee1d327308e67ff63732833b413b189ebcb77cdb3fc65bbd7417ecbfc8575775ff79550678bce020 WHIRLPOOL 4ff63737b01eca22bc1dcd7e61a81ad3285c90ac1e03764edffe85b003eade780a936bbd74773f8d58d2a34dbe562bdfe332c5dd8ddd052f5a3928caa736d882
+DIST Pyro4-4.47.tar.gz 437077 SHA256 9354b722f9f5965ade5839241c8d7ff06ec2fac678a2c9e197a63966da241c89 SHA512 5879cad65ba32fc735d002037bbdb9ee1ef7e61e169306f5ec5e6bb771478c17ddde621d8b73ff4ddff8ffb1307a25f7851bc5c96f8ff8689aa6d74d1157cd8b WHIRLPOOL 4e81666ca26d6bef337b952db5f906e37deb5e544bc936bc6fc798378102dfee3e24c03b8e69dfd6e7e4ba42d96a82310709ef98430d4a47c4a094048cca49fd

dev-python/pyro/pyro-4.47.ebuild

@@ -0,0 +1,84 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 python3_{3,4,5} pypy )
+
+inherit distutils-r1
+
+MY_PN="Pyro4"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Distributed object middleware for Python (RPC)"
+HOMEPAGE="http://www.xs4all.nl/~irmen/pyro/ https://pypi.python.org/pypi/Pyro4 https://github.com/irmen/Pyro4"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="4"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc examples test"
+
+RDEPEND="
+	!dev-python/pyro:0
+	$(python_gen_cond_dep \
+		'dev-python/selectors34[${PYTHON_USEDEP}]' python{2_7,3_3})
+	>=dev-python/serpent-1.11[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/coverage[${PYTHON_USEDEP}]
+		dev-python/dill[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+	)"
+
+S="${WORKDIR}/${MY_P}"
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_prepare_all() {
+	sed \
+		-e '/sys.path.insert/a sys.path.insert(1,"PyroTests")' \
+		-i tests/run_testsuite.py || die
+
+	# Disable tests requiring network connection.
+	sed \
+		-e "s/testBCstart/_&/" \
+		-e "s/testDaemonPyroObj/_&/" \
+		-e "s/testLookupAndRegister/_&/" \
+		-e "s/testMulti/_&/" \
+		-e "s/testRefuseDottedNames/_&/" \
+		-e "s/testResolve/_&/" \
+		-e "s/testBCLookup/_&/" \
+		-e "s/testLookupInvalidHmac/_&/" \
+		-e "s/testLookupUnixsockParsing/_&/" \
+		-e "s/testPyroname/_&/" \
+		-i tests/PyroTests/test_naming.py || die
+	sed \
+		-e "s/testOwnloopBasics/_&/" \
+		-e "s/testStartNSfunc/_&/" \
+		-i tests/PyroTests/test_naming2.py || die
+
+	sed \
+		-e "s/testServerConnections/_&/" \
+	    -e "s/testServerParallelism/_&/" \
+		-i tests/PyroTests/test_server.py || die
+
+	sed \
+		-e "s/testBroadcast/_&/" \
+		-e "s/testGetIP/_&/" \
+		-e "s/testGetIpVersion[46]/_&/" \
+		-i tests/PyroTests/test_socket.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	pushd "${S}"/tests >/dev/null || die
+	PYTHONPATH=../src ${PYTHON} run_testsuite.py || die
+	popd >/dev/null || die
+}
+
+python_install_all() {
+	use doc && HTML_DOCS=( docs/. )
+	use examples && local EXAMPLES=( examples/. )
+	distutils-r1_python_install_all
+}