dev-python/awscli: 1.18.117 bump; relax rsa dependency.

Bug: https://bugs.gentoo.org/714866
Signed-off-by: Piotr Karbowski <slashbeast@gentoo.org>

dev-python/awscli/Manifest

@@ -1 +1,2 @@
+DIST awscli-1.18.117.tar.gz 1846974 BLAKE2B 7da993763f9e3082cf66a39c474e857885b33a6fe4ad136faaa1589e2c7ffc59daf6628f01dff867e8f2e92b0feb2881fab0ec45128b6ebed327454f3884679b SHA512 96e8ef0b217e1fcfb2e6995aecea81501c35ce8d050e82f77d58c5d68e4bd4ed0b0aff9dd91f7b69aac2c6d455d85188e1f855e685b05fc60c9f79630eb7c87d
 DIST awscli-1.18.70.tar.gz 1758807 BLAKE2B 493bb9193ebf3f01e8088c4928036ef806d2a2802b3de6bfc7ca7c2f17d655a367601876be939e89fa7c28b4a7f5a5b6c9286707d3ddd1f7339cfcc35e2f85de SHA512 f81f7077299291a80a2965da91f2f09ca40918bc12faa3312030f5783df73503d61da9765bef4b17b71b318a71f8808dda9ede0aa276c4f055b2d5a69e299c1a

dev-python/awscli/awscli-1.18.117.ebuild

@@ -0,0 +1,56 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit bash-completion-r1 distutils-r1
+
+DESCRIPTION="Universal Command Line Environment for AWS"
+HOMEPAGE="https://pypi.org/project/awscli/"
+#SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
+SRC_URI="https://github.com/aws/aws-cli/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="test"
+
+# requires network access
+RESTRICT="test"
+
+RDEPEND="
+	>=dev-python/botocore-1.16.20[${PYTHON_USEDEP}]
+	<dev-python/colorama-0.4.4[${PYTHON_USEDEP}]
+	dev-python/docutils[${PYTHON_USEDEP}]
+	dev-python/rsa[${PYTHON_USEDEP}]
+	>=dev-python/s3transfer-0.3.0[${PYTHON_USEDEP}]
+	<dev-python/pyyaml-5.4.0[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}"
+
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+	)
+"
+
+S="${WORKDIR}/aws-cli-${PV}"
+
+python_test() {
+	nosetests -vv || die
+}
+
+python_install_all() {
+	newbashcomp bin/aws_bash_completer aws
+
+	insinto /usr/share/zsh/site-functions
+	newins bin/aws_zsh_completer.sh _aws
+
+	distutils-r1_python_install_all
+
+	rm "${ED}"/usr/bin/{aws.cmd,aws_bash_completer,aws_zsh_completer.sh} || die
+}