diff --git a/dev-python/rq/Manifest b/dev-python/rq/Manifest
index 19227f34b943..91f17104f95c 100644
--- a/dev-python/rq/Manifest
+++ b/dev-python/rq/Manifest
@@ -1 +1,2 @@
 DIST rq-2.4.0.tar.gz 661530 BLAKE2B bc9e379839ef281a340cc41848f351827d075e75fe303009fbec9ba285ca9c5cc9ac405e04f3d5066956b794a79b6394f5bff9bfa935a5ee3d028ee7dfd56641 SHA512 da80c91a2b632141ddf176bc6389ee2a598dc21c2115ffc3fc9166b08ce18c4c3796ed3a6627e184d0920d8354981bb5475457f66bcc9b51f0ffa0f7f2715eed
+DIST rq-2.4.1.tar.gz 664540 BLAKE2B e5e8617c165c555b150fc3e8d6eacdfb697d6490cf5d972eaf78437a92d70c80e3a8c36e399e85716f30bf0a80a87f49602abc50ad98074aa228dcfb2c99ad4a SHA512 4a4dc8810f2cfda8ec7af722358ccf18b61fdd2898177224ca1d686f1d20483518419adc88027bb671bc38e605894244189c0c0c6eabbaab0550a4ae632457da
diff --git a/dev-python/rq/rq-2.4.1.ebuild b/dev-python/rq/rq-2.4.1.ebuild
new file mode 100644
index 000000000000..96aa7044b36d
--- /dev/null
+++ b/dev-python/rq/rq-2.4.1.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Simple, lightweight library for creating and processing background jobs"
+HOMEPAGE="
+	https://python-rq.org/
+	https://github.com/rq/rq/
+	https://pypi.org/project/rq/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/click-5.0[${PYTHON_USEDEP}]
+	>=dev-python/redis-4.5.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-db/redis
+		dev-python/psutil[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# strip pin
+	sed -i -e '/dependencies/s:,!=[0-9.]*::' pyproject.toml || die
+}
+
+src_test() {
+	local redis_pid="${T}"/redis.pid
+	local redis_port=6379
+	local redis_test_config="daemonize yes
+		pidfile ${redis_pid}
+		port ${redis_port}
+		bind 127.0.0.1
+	"
+
+	# Spawn Redis itself for testing purposes
+	# NOTE: On sam@'s machine, spawning Redis can hang in the sandbox.
+	# I'm not restricting tests yet because this doesn't happen for anyone else AFAICT.
+	einfo "Spawning Redis"
+	einfo "NOTE: Port ${redis_port} must be free"
+	/usr/sbin/redis-server - <<< "${redis_test_config}" || die
+
+	# Run the actual tests
+	distutils-r1_src_test
+
+	# Clean up afterwards
+	kill "$(<"${redis_pid}")" || die
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# requires <sentry-sdk-2
+		tests/test_sentry.py::TestSentry::test_failure_capture
+		# hang
+		tests/test_commands.py::TestCommands::test_shutdown_command
+		tests/test_worker_pool.py::TestWorkerPool::test_check_workers
+		tests/test_dependencies.py::TestDependencies
+		# already present in older versions
+		tests/test_spawn_worker.py::TestWorker::test_work_and_quit
+	)
+
+	epytest
+}