diff --git a/dev-python/spyder-kernels/Manifest b/dev-python/spyder-kernels/Manifest
index 2c6fff0f3c71c..ef401dc4f8e7a 100644
--- a/dev-python/spyder-kernels/Manifest
+++ b/dev-python/spyder-kernels/Manifest
@@ -1,2 +1,3 @@
 DIST spyder-kernels-3.0.1.gh.tar.gz 238107 BLAKE2B bf2b67555b561e935e13cc8bedfe178396f100252f3a0a2f8606971691c62d2bba64fc2cae443654aadd3a853674184eaaa3567855ce1c1358f5142f40c5ca74 SHA512 a16fe124f4abf36bc95f2e409391c550063f5fc00024c3b58b635eb03ca449678065daa25c27c42a4a85babd6fcbf80ab6423e519221c3916c8ddbb03c0056b3
 DIST spyder-kernels-3.0.2.gh.tar.gz 239620 BLAKE2B d1661dccd5746afb377de4a6e78ebb169ad887df54b31afe1e290f2c34616a23b089b8c02ee5b0fac67dce3ab550f5908dd4d62cde8e2de1486a0553912c4410 SHA512 5bc64e8802a961dab124ae251f66c5987bf4125c57df6d25e209ce49bb49e63ea21dddcf75d524f93109205d48f3aec92a487b8b9faae3c1cdbd9cb9a206ad72
+DIST spyder-kernels-3.0.3.gh.tar.gz 240072 BLAKE2B 99fe0e7ecae61b717ce0215a6789742ed5f684fcc700d911388c4ca481e37dee829014b1b1633ba110a669bba3636ef250f94777d8c501f682c4fb53288e469f SHA512 4335c0401da8cc0a13db2888acf740e20ec9c21ad29b9375806b0958b81649623cd672f2d4579059b083fba11ec1e42acc28c0da76c3f7d3c0510b64006d32c7
diff --git a/dev-python/spyder-kernels/spyder-kernels-3.0.3.ebuild b/dev-python/spyder-kernels/spyder-kernels-3.0.3.ebuild
new file mode 100644
index 0000000000000..6c11b54f8730a
--- /dev/null
+++ b/dev-python/spyder-kernels/spyder-kernels-3.0.3.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{10..13} )
+
+inherit distutils-r1
+
+DESCRIPTION="Kernels used by spyder on its ipython console"
+HOMEPAGE="
+	https://github.com/spyder-ide/spyder-kernels/
+	https://pypi.org/project/spyder-kernels/
+"
+SRC_URI="https://github.com/spyder-ide/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	dev-python/cloudpickle[${PYTHON_USEDEP}]
+	<dev-python/ipykernel-7[${PYTHON_USEDEP}]
+	>=dev-python/ipykernel-6.29.3[${PYTHON_USEDEP}]
+	<dev-python/ipython-9[${PYTHON_USEDEP}]
+	>dev-python/ipython-8.13.0[${PYTHON_USEDEP}]
+	<dev-python/jupyter-client-9[${PYTHON_USEDEP}]
+	>=dev-python/jupyter-client-7.4.9[${PYTHON_USEDEP}]
+	dev-python/matplotlib-inline[${PYTHON_USEDEP}]
+	>=dev-python/pyxdg-0.26[${PYTHON_USEDEP}]
+	>=dev-python/pyzmq-24.0.0[${PYTHON_USEDEP}]
+	>=dev-python/wurlitzer-1.0.3[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		dev-python/cython[${PYTHON_USEDEP}]
+		dev-python/django[${PYTHON_USEDEP}]
+		dev-python/flaky[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/h5py[${PYTHON_USEDEP}]
+			dev-python/pandas[${PYTHON_USEDEP}]
+			dev-python/xarray[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# we no longer package distributed, and also removed dependency on dask
+		spyder_kernels/console/tests/test_console_kernel.py::test_dask_multiprocessing
+
+		# RuntimeError: There is no current event loop in thread 'MainThread'.
+		# https://bugs.gentoo.org/834893
+		spyder_kernels/console/tests/test_console_kernel.py::test_cwd_in_sys_path
+		spyder_kernels/console/tests/test_console_kernel.py::test_multiprocessing
+		spyder_kernels/console/tests/test_console_kernel.py::test_multiprocessing_2
+		spyder_kernels/console/tests/test_console_kernel.py::test_runfile
+		spyder_kernels/console/tests/test_console_kernel.py::test_np_threshold
+		spyder_kernels/console/tests/test_console_kernel.py::test_turtle_launch
+		spyder_kernels/console/tests/test_console_kernel.py::test_matplotlib_inline
+
+		# pydicom only packaged in ::sci at the moment
+		spyder_kernels/utils/tests/test_iofuncs.py::test_load_dicom_files
+	)
+	local EPYTEST_IGNORE=()
+
+	if ! has_version "dev-python/pandas[${PYTHON_USEDEP}]"; then
+		EPYTEST_IGNORE+=(
+			# require pandas
+			spyder_kernels/utils/tests/test_nsview.py
+		)
+	fi
+
+	if ! has_version "dev-python/h5py[${PYTHON_USEDEP}]"; then
+		EPYTEST_DESELECT+=(
+			# require hdf5
+			spyder_kernels/utils/tests/test_iofuncs.py::test_save_load_hdf5_files
+			spyder_kernels/utils/tests/test_dochelpers.py
+		)
+	fi
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}