dev-lua/readline: add 3.2

Signed-off-by: Conrad Kostecki <conikost@gentoo.org>
This commit is contained in:
Conrad Kostecki
2022-10-02 01:15:07 +02:00
parent 12a1436c9f
commit 63d122007b
2 changed files with 95 additions and 0 deletions
+1
View File
@@ -1 +1,2 @@
DIST lua-readline-3.1.tar.gz 16114 BLAKE2B 372bc61573b20c8ebf66bb684624dde9d5ce7868543294450ef3d47bba5a042c5d7f4262366f2de2db8d3d92bbf7fb4895d29577af34307d7b145e6f913ec957 SHA512 d3bee61b6c876e96d2c1097e29862a3f16d1e666b1087e58899f59a3115f9af31793492edfcc3f3802565f98f276960d382a89c0b6cfb1d54acfd37ad006b74b
DIST lua-readline-3.2.tar.gz 16215 BLAKE2B 889db8cfefc37008fac9f92b6ef071147763d00f01ca42b31646594e812ab936187e65e8959e723be409d21c3e3cc2d93fe52eafac79e37b7d0cec2216d8accf SHA512 d605b99f2fa06920e67125b462f257f8cd263912b6ffba173bee77425c77f6b08b463ec4c0851c81dfc23e736698c9fbbb40e8a935cada2329b6a8e02a6cdaad
+94
View File
@@ -0,0 +1,94 @@
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
LUA_COMPAT=( lua5-{1..4} luajit )
inherit lua toolchain-funcs
DESCRIPTION="A simple interface to the readline and history libraries"
HOMEPAGE="https://pjb.com.au/comp/lua/readline.html"
SRC_URI="https://pjb.com.au/comp/lua/${P}.tar.gz -> lua-${P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~x86"
REQUIRED_USE="${LUA_REQUIRED_USE}"
# Tests are interactive
RESTRICT="test"
RDEPEND="
dev-lua/luaposix
sys-libs/readline:=
"
DEPEND="${RDEPEND}"
BDEPEND="virtual/pkgconfig"
src_prepare() {
default
lua_copy_sources
}
lua_src_compile() {
pushd "${BUILD_DIR}" || die
local compiler=(
"$(tc-getCC)"
"${CFLAGS}"
"-fPIC"
"$(lua_get_CFLAGS)"
"-c C-readline.c"
"-o C-readline.o"
)
einfo "${compiler[@]}"
${compiler[@]} || die
local linker=(
"$(tc-getCC)"
"-shared"
"${LDFLAGS}"
"$($(tc-getPKG_CONFIG) --libs readline)"
"-o C-readline.so"
"C-readline.o"
)
einfo "${linker[@]}"
${linker[@]} || die
popd
}
src_compile() {
lua_foreach_impl lua_src_compile
}
lua_src_test() {
pushd "${BUILD_DIR}" || die
LUA_CPATH="./?.so;${ESYSROOT}/usr/$(get_libdir)/lua/$(ver_cut 1-2 $(lua_get_version))/?.so" ${ELUA} test/test_rl.lua || die
popd || die
}
src_test() {
lua_foreach_impl lua_src_test
}
lua_src_install() {
pushd "${BUILD_DIR}" || die
insinto "$(lua_get_cmod_dir)"
doins C-readline.so
insinto "$(lua_get_lmod_dir)"
doins readline.lua
popd || die
}
src_install() {
lua_foreach_impl lua_src_install
docinto html
dodoc doc/readline.html
}