diff --git a/dev-python/zlib-ng/Manifest b/dev-python/zlib-ng/Manifest
new file mode 100644
index 0000000000000..d7ead4051870a
--- /dev/null
+++ b/dev-python/zlib-ng/Manifest
@@ -0,0 +1 @@
+DIST python-zlib-ng-0.5.1.gh.tar.gz 3381700 BLAKE2B 9c9c460c60a10fa5f24816f6f4562f4feeef585c70da34bb0fe0ea2b9c43e62f19f1559a0dd74a48659b02561d3ba505fc3b1b399249a0d8d0603695f7c44db5 SHA512 98d689d6d3462310cdec4d73ec63ee2a8842b54ae5285c7765629b2385a23234bfec45207fedd1e36cca58e7388cb49c34e8bef5f4e102c61e624c80e488492e
diff --git a/dev-python/zlib-ng/metadata.xml b/dev-python/zlib-ng/metadata.xml
new file mode 100644
index 0000000000000..703b00e747da0
--- /dev/null
+++ b/dev-python/zlib-ng/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">pycompression/python-zlib-ng</remote-id>
+		<remote-id type="pypi">zlib-ng</remote-id>
+	</upstream>
+</pkgmetadata>
diff --git a/dev-python/zlib-ng/zlib-ng-0.5.1.ebuild b/dev-python/zlib-ng/zlib-ng-0.5.1.ebuild
new file mode 100644
index 0000000000000..2dd282d129904
--- /dev/null
+++ b/dev-python/zlib-ng/zlib-ng-0.5.1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3_11 python3_{11..13} )
+
+inherit distutils-r1
+
+MY_P=python-zlib-ng-${PV}
+DESCRIPTION="Drop-in replacement for zlib and gzip modules using zlib-ng"
+HOMEPAGE="
+	https://github.com/pycompression/python-zlib-ng/
+	https://pypi.org/project/zlib-ng/
+"
+# no tests in sdist, as of 0.5.1
+# same upstream as dev-python/isal, so let's see how that report goes:
+# https://github.com/pycompression/python-isal/issues/231
+SRC_URI="
+	https://github.com/pycompression/python-zlib-ng/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="PSF-2"
+SLOT="0"
+KEYWORDS="~amd64"
+
+DEPEND="
+	sys-libs/zlib-ng:=
+"
+RDEPEND="
+	${DEPEND}
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_configure() {
+	export PYTHON_ZLIB_NG_LINK_DYNAMIC=1
+
+	# why people can't use setuptools-scm...
+	sed -i -e '/versioningit/d' setup.py || die
+	sed -i -e 's/versioningit/ignoreme/' pyproject.toml || die
+	echo "[metadata]" >> setup.cfg || die
+	echo "version = ${PV}" >> setup.cfg || die
+	echo "__version__ = '${PV}'" > src/zlib_ng/_version.py || die
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest tests
+}