games-engines/devilutionx: drop 1.5.2

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

games-engines/devilutionx/Manifest

@@ -1,2 +1 @@
-DIST devilutionx-1.5.2.tar.xz 21968848 BLAKE2B 5a8c280f262e2d0f47ee5978cfc858ea62481eac838ad691996f359f1c4889499e4c78b5e6a1f2dc998cf0fc89ebbdf79296a25adb411e30e9248cce1b07d3a8 SHA512 b7fd5814c8671e439d4349297cfda0d89eb1f7a0945ec11bdf7a83637371664c9c39c036249e1650911397111e1b5d9e931f221ffd2d4a1f9e80d5ca58357dcf
 DIST devilutionx-1.5.3.tar.xz 22394112 BLAKE2B 1b04c7fe334ddfd6b1eb619b1e86c1e429f6c26c980a16129d8322bb30641409d9d11a203e42ccdbce60a05e00dc49b1a2acbdd1007c5f99e40b88acd1251440 SHA512 619873bb232d1b344f5001c232364af9cfcda72e44f28fd2a15332292fa37c0e64b7fccade3570b96bd648be235ed56e0cc2e3fd8299ac57ef26f2ce844cbc2f

games-engines/devilutionx/devilutionx-1.5.2.ebuild

@@ -1,89 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit cmake xdg
-
-DESCRIPTION="Diablo engine for modern operating systems"
-HOMEPAGE="https://github.com/diasurgical/devilutionX/"
-SRC_URI="
-	https://github.com/diasurgical/devilutionX/releases/download/${PV}/devilutionx-src.tar.xz
-		-> ${P}.tar.xz
-"
-S=${WORKDIR}/${PN}-src-${PV}
-
-LICENSE="Unlicense CC-BY-4.0 GPL-2+ LGPL-2.1+ MIT OFL-1.1 zerotier? ( BUSL-1.1 )"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="debug +sodium test zerotier"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	app-arch/bzip2:=
-	dev-libs/libfmt:=
-	media-libs/libsdl2[haptic,joystick,opengl,video]
-	media-libs/sdl2-image[png]
-	media-libs/sdl_audiolib
-	sys-libs/zlib:=
-	sodium? ( dev-libs/libsodium:= )
-"
-DEPEND="
-	${RDEPEND}
-	dev-cpp/asio
-	dev-cpp/simpleini
-	test? ( dev-cpp/gtest )
-"
-BDEPEND="
-	sys-devel/gettext
-"
-
-src_prepare() {
-	cmake_src_prepare
-
-	# use system asio
-	echo 'add_library(asio INTERFACE)' > 3rdParty/asio/CMakeLists.txt || die
-
-	# ensure system copies are used
-	rm -r dist/{asio,simpleini,sdl_audiolib}-src || die
-}
-
-src_configure() {
-	local mycmakeargs=(
-		-DBUILD_TESTING=$(usex test)
-		-DCCACHE_PROGRAM=no #813768
-		-DDEBUG=$(usex debug)
-		-DDISABLE_LTO=yes # let CFLAGS control this
-		-DDISABLE_ZERO_TIER=$(usex !zerotier)
-		-DPACKET_ENCRYPTION=$(usex sodium)
-		-DPIE=yes
-	)
-
-	cmake_src_configure
-}
-
-src_test() {
-	# timedemo tests only pass when game assets are available
-	cmake_src_test -E Timedemo.
-}
-
-src_install() {
-	local DOCS=( Packaging/nix/README.txt docs/*.md )
-	cmake_src_install
-
-	rm -- "${ED}"/usr/share/diasurgical/devilutionx/README.txt || die
-}
-
-pkg_postinst() {
-	xdg_pkg_postinst
-
-	if [[ ! ${REPLACING_VERSIONS} ]]; then
-		elog "In order to play the game, you will need to copy the following data file"
-		elog "from the original game, and optionally the hellfire expansion files:"
-		elog "	- DIABDAT.MPQ"
-		elog "	- hellfire.mpq hfmonk.mpq hfmusic.mpq hfvoice.mpq"
-		elog "to ~/.local/share/diasurgical/devilution/"
-		elog
-		elog "See ${EROOT}/usr/share/doc/${PF}/README.txt* for details."
-	fi
-}