mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-09 18:47:16 -08:00
dev-cpp/libgnomecanvasmm: update EAPI 5 -> 8
Bug: https://bugs.gentoo.org/808375 Signed-off-by: David Seifert <soap@gentoo.org>
This commit is contained in:
+13
@@ -0,0 +1,13 @@
|
||||
don't waste time building the examples
|
||||
|
||||
--- a/Makefile.in
|
||||
+++ b/Makefile.in
|
||||
@@ -195,7 +195,7 @@
|
||||
top_build_prefix = @top_build_prefix@
|
||||
top_builddir = @top_builddir@
|
||||
top_srcdir = @top_srcdir@
|
||||
-SUBDIRS = tools libgnomecanvas docs examples demos
|
||||
+SUBDIRS = tools libgnomecanvas docs demos
|
||||
DIST_SUBDIRS = $(SUBDIRS) scripts
|
||||
EXTRA_DIST = libgnomecanvasmm.spec.in \
|
||||
build_shared/Makefile_build.am_fragment \
|
||||
@@ -1,56 +0,0 @@
|
||||
# Copyright 1999-2020 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI="5"
|
||||
GCONF_DEBUG="no"
|
||||
GNOME_TARBALL_SUFFIX="bz2"
|
||||
|
||||
inherit flag-o-matic gnome2
|
||||
|
||||
DESCRIPTION="C++ bindings for libgnomecanvas"
|
||||
HOMEPAGE="https://www.gtkmm.org"
|
||||
|
||||
LICENSE="LGPL-2.1"
|
||||
SLOT="2.6"
|
||||
KEYWORDS="~alpha amd64 arm ~ia64 ppc ppc64 sparc x86"
|
||||
IUSE="doc examples"
|
||||
|
||||
RDEPEND="
|
||||
>=gnome-base/libgnomecanvas-2.6
|
||||
>=dev-cpp/gtkmm-2.4:2.4
|
||||
"
|
||||
DEPEND="${RDEPEND}
|
||||
virtual/pkgconfig
|
||||
doc? ( app-doc/doxygen )
|
||||
"
|
||||
|
||||
src_prepare() {
|
||||
if ! use examples; then
|
||||
# don't waste time building the examples
|
||||
sed -i 's/^\(SUBDIRS =.*\)examples\(.*\)$/\1\2/' Makefile.in || \
|
||||
die "sed Makefile.in failed"
|
||||
fi
|
||||
gnome2_src_prepare
|
||||
append-cxxflags -std=c++11 #568300
|
||||
}
|
||||
|
||||
src_compile() {
|
||||
gnome2_src_compile
|
||||
|
||||
if use doc; then
|
||||
cd "${S}/docs/reference"
|
||||
emake all
|
||||
fi
|
||||
}
|
||||
|
||||
src_install() {
|
||||
gnome2_src_install
|
||||
|
||||
if use doc ; then
|
||||
dohtml -r docs/reference/html/*
|
||||
fi
|
||||
|
||||
if use examples; then
|
||||
cp -R examples "${D}/usr/share/doc/${PF}"
|
||||
fi
|
||||
}
|
||||
@@ -0,0 +1,45 @@
|
||||
# Copyright 1999-2022 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
GNOME_TARBALL_SUFFIX="bz2"
|
||||
|
||||
inherit gnome2
|
||||
|
||||
DESCRIPTION="C++ bindings for libgnomecanvas"
|
||||
HOMEPAGE="https://www.gtkmm.org"
|
||||
|
||||
LICENSE="LGPL-2.1"
|
||||
SLOT="2.6"
|
||||
KEYWORDS="~alpha amd64 arm ~ia64 ppc ppc64 sparc x86"
|
||||
IUSE="doc"
|
||||
|
||||
RDEPEND="
|
||||
>=gnome-base/libgnomecanvas-2.6
|
||||
>=dev-cpp/gtkmm-2.4:2.4
|
||||
"
|
||||
DEPEND="${RDEPEND}"
|
||||
BDEPEND="
|
||||
virtual/pkgconfig
|
||||
doc? ( app-doc/doxygen )
|
||||
"
|
||||
|
||||
PATCHES=( "${FILESDIR}"/${P}-disable-building-examples.patch )
|
||||
|
||||
src_compile() {
|
||||
gnome2_src_compile
|
||||
|
||||
if use doc; then
|
||||
emake -C docs/reference all
|
||||
HTML_DOCS=( docs/reference/html/. )
|
||||
fi
|
||||
}
|
||||
|
||||
src_install() {
|
||||
gnome2_src_install
|
||||
|
||||
rm examples/Makefile* examples/*/Makefile* || die
|
||||
dodoc -r examples
|
||||
docompress -x /usr/share/doc/${PF}/examples
|
||||
}
|
||||
Reference in New Issue
Block a user