From 5fac145fe1ee37313fa9e6af6016f8e52b515d40 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Sat, 14 Jun 2025 05:41:50 +0200
Subject: [PATCH] dev-python/pdm: Bump to 2.25.0
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/pdm/Manifest          |  1 +
 dev-python/pdm/pdm-2.25.0.ebuild | 81 ++++++++++++++++++++++++++++++++
 2 files changed, 82 insertions(+)
 create mode 100644 dev-python/pdm/pdm-2.25.0.ebuild

diff --git a/dev-python/pdm/Manifest b/dev-python/pdm/Manifest
index e0be67dd15dc4..fb881cf06e174 100644
--- a/dev-python/pdm/Manifest
+++ b/dev-python/pdm/Manifest
@@ -1,2 +1,3 @@
 DIST pdm-2.24.1.tar.gz 2655876 BLAKE2B 557a1a8dac5fe2770a46f9f9baf17ee334795c88f17347924b5450dd681ac90da8c13f184020ee1d200d3d41bc91a6dadde98c210f3a7707c2ee8c83418b917c SHA512 5e41ffeeb8ebf431c840b156caa72e86c22313589f31430258c5002508cb9956f2bbf723c168697721bedb79af7d90bed54a00d53ad1a226f613324830a32146
 DIST pdm-2.24.2.tar.gz 2657737 BLAKE2B 8652b489d25f7b0bb3b60bf49ed136985b96aa2b7ac4fcbbe6e958e3dfe835dbc56684dd1a1a398bf103d91145dbccc377fb88e1d50ed045aebcf551917e092a SHA512 46c26f2384cefe73e361ee442b60dede14ecb14bd04844578f9b9fbda919f016026269d08776da70fb0f7bce41c061ba3b0874ef81c4d0eaf70a7e270c1cbcf2
+DIST pdm-2.25.0.tar.gz 2662202 BLAKE2B d42f3344904f87f83d6e24fb7a46d27a2981da7c68acc099cb5759f14f03f0191622dfe4c5abe5408340868d889dcdec632597019b858c99e9dfdf952dd29673 SHA512 6b57f7d3ce69fa6b7de1e6b93f7defecd181b6f445a2075999faa9a45be87f79a54bbcb03e415ec2c6448eb3abde411c2a1de0ca163e45a5accbac105d21415c
diff --git a/dev-python/pdm/pdm-2.25.0.ebuild b/dev-python/pdm/pdm-2.25.0.ebuild
new file mode 100644
index 0000000000000..5e9e71dd639ec
--- /dev/null
+++ b/dev-python/pdm/pdm-2.25.0.ebuild
@@ -0,0 +1,81 @@
+# Copyright 2023-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=pdm-backend
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python package and dependency manager supporting the latest PEP standards"
+HOMEPAGE="
+	https://pdm-project.org/
+	https://github.com/pdm-project/pdm/
+	https://pypi.org/project/pdm/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+RDEPEND="
+	dev-python/certifi[${PYTHON_USEDEP}]
+	>=dev-python/dep-logic-0.5[${PYTHON_USEDEP}]
+	<dev-python/findpython-1[${PYTHON_USEDEP}]
+	>=dev-python/findpython-0.6.0[${PYTHON_USEDEP}]
+	dev-python/blinker[${PYTHON_USEDEP}]
+	dev-python/filelock[${PYTHON_USEDEP}]
+	>=dev-python/hishel-0.0.32[${PYTHON_USEDEP}]
+	>=dev-python/httpcore-1.0.6[${PYTHON_USEDEP}]
+	dev-python/httpx[${PYTHON_USEDEP}]
+	>=dev-python/id-1.5.0[${PYTHON_USEDEP}]
+	dev-python/installer[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	>=dev-python/pbs-installer-2025.06.06[${PYTHON_USEDEP}]
+	dev-python/platformdirs[${PYTHON_USEDEP}]
+	dev-python/pyproject-hooks[${PYTHON_USEDEP}]
+	dev-python/python-dotenv[${PYTHON_USEDEP}]
+	>=dev-python/resolvelib-1.1[${PYTHON_USEDEP}]
+	dev-python/rich[${PYTHON_USEDEP}]
+	dev-python/shellingham[${PYTHON_USEDEP}]
+	dev-python/tomlkit[${PYTHON_USEDEP}]
+	>=dev-python/truststore-0.9[${PYTHON_USEDEP}]
+	>=dev-python/unearth-0.17.5[${PYTHON_USEDEP}]
+	dev-python/virtualenv[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/msgpack[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/pytest-httpserver[${PYTHON_USEDEP}]
+		dev-python/pytest-httpx[${PYTHON_USEDEP}]
+		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+		dev-python/uv
+	)
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# unpin deps
+	sed -i -e 's:,<[0-9.a]*::' pyproject.toml || die
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Internet
+		'tests/models/test_candidates.py::test_expand_project_root_in_url[demo @ file:///${PROJECT_ROOT}/tests/fixtures/artifacts/demo-0.0.1.tar.gz]'
+		# unhappy about extra packages being installed?
+		# (also fails randomly in venv)
+		tests/cli/test_build.py::test_build_with_no_isolation
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest  -m "not network and not integration and not path" \
+		-p pytest_mock -p pytest_httpx -p pytest_httpserver
+}