dev-python/mysql-connector-python: bump to v8.0.19

Package-Manager: Portage-2.3.88, Repoman-2.3.20
Signed-off-by: Thomas Deutschmann <whissi@gentoo.org>

dev-python/mysql-connector-python/Manifest

@@ -1,2 +1,3 @@
 DIST mysql-connector-python-2.1.7.tar.gz 11781659 BLAKE2B 332092059a32249e449f99540beb9eebf80e9381cef4560208412a19385894eb2193f02d5a20aceafe9644b8a225926a02d57c3acc89ba7d321b6d0f9c7c4d76 SHA512 f88c3a6dd3c3c1cd5c16165daef801dbcc7ea9163406273dd751e25687a57dcdf4ffbcdb65bb107e8cd9d7c91029823f625dc19ab34116398263fa074598880a
 DIST mysql-connector-python-8.0.18.tar.gz 12037201 BLAKE2B 54dc45c9ecc09bad755bafec2b3b73e35368f742f30c8644764c8c892c6f79c3b6b438cf38dd9ebc878cd76d5d74d71be6668a903b57b3d0feaba9ff6f5b58cc SHA512 cb441a6388de8609b56e4d9885ae2491d207c7b1e3bb387341d55853d383eff6e268e34feb32b42797c7b210d35f9d6dbc302ea4c9ed2441a76b91ea66d504b2
+DIST mysql-connector-python-8.0.19.tar.gz 12051609 BLAKE2B 252d4ee650c1eddbe54575451ac378236b6a795237c445239ecec096c7adcb60da2244592f083a50df57c9e2ae6447f1dcaf861042973a31c3fe7292509ef93d SHA512 9137b0b6aafbff16c83f59ab03da810232a92f6b76e38f460782153c5ddbdf6ae55d0c72a0c7902b7bc05ad1010bdc849662cd3d2138ae93476abf013e7a508f

dev-python/mysql-connector-python/mysql-connector-python-8.0.19.ebuild

@@ -0,0 +1,52 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+inherit distutils-r1
+
+DESCRIPTION="Python client library for MariaDB/MySQL"
+HOMEPAGE="https://dev.mysql.com/downloads/connector/python/"
+SRC_URI="https://dev.mysql.com/get/Downloads/Connector-Python/${P}.tar.gz"
+
+KEYWORDS="~amd64 ~arm ~x86"
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="examples test"
+
+BDEPEND=">=dev-libs/protobuf-3.6.1"
+
+RDEPEND="
+	>=dev-db/mysql-connector-c-8.0
+	>=dev-python/protobuf-python-3.6.1[${PYTHON_USEDEP}]
+"
+# tests/mysqld.py does not like MariaDB version strings.
+# See the regex MySQLServerBase._get_version.
+DEPEND="${RDEPEND} test? ( dev-db/mysql[server(+)] )"
+
+# Tests currently fail.
+# mysql.connector.errors.DatabaseError: 1300 (HY000): Invalid utf8 character string: ''
+RESTRICT="test"
+
+DOCS=( README.txt CHANGES.txt README.rst )
+
+python_test() {
+	"${EPYTHON}" unittests.py --with-mysql="${EPREFIX}/usr" --unix-socket="${T}" --mysql-topdir="${T}"
+}
+
+# Yeah, this is really broken, but the extension will only build this way during "install"
+python_install() {
+	distutils-r1_python_install \
+		--with-mysql-capi="${EPREFIX}/usr" \
+		--with-protobuf-include-dir="${EPREFIX}/usr/include/google/protobuf/" \
+		--with-protobuf-lib-dir="${EPREFIX}/usr/$(get_libdir)" \
+		--with-protoc="${EPREFIX}/usr/bin/protoc"
+}
+
+python_install_all(){
+	distutils-r1_python_install_all
+	if use examples ; then
+		dodoc -r examples
+	fi
+}