From 5fa4e5e4509b54060914e28a2777c190b53d3da4 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Sat, 13 Dec 2025 08:46:58 +0100
Subject: [PATCH] dev-python/authlib: Bump to 1.6.6
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/authlib/Manifest             |  1 +
 dev-python/authlib/authlib-1.6.6.ebuild | 74 +++++++++++++++++++++++++
 2 files changed, 75 insertions(+)
 create mode 100644 dev-python/authlib/authlib-1.6.6.ebuild

diff --git a/dev-python/authlib/Manifest b/dev-python/authlib/Manifest
index 40f5c5df89d9..12671cceca42 100644
--- a/dev-python/authlib/Manifest
+++ b/dev-python/authlib/Manifest
@@ -1 +1,2 @@
 DIST authlib-1.6.5.gh.tar.gz 328496 BLAKE2B 8065cbeaa699671d7ab5a8463f48b5ebfd3d13fe6282829ee84efea2558beacee1838a5fac8d0244469aac1d486c49b30d8638765d54f16c5d27f669bcbecf08 SHA512 ddb9e51690cbaa6d990ac35a180def19808ccb95e08aedf5351d61717cf141358fb749ae593f1cbdf6274ca97c9c49a7085c973461825a631604ab6e6cbf1693
+DIST authlib-1.6.6.gh.tar.gz 329249 BLAKE2B cab561d2a9faf2eba0392ebbf4a6ca7c79474591eba4d2e02548c7893f8988af9c9e8e366f6cb02051a64953c7e4425493231e0738e8953d003d5d122b1dd407 SHA512 5b9f6043503d3d709620fd853a0f5405f213bbff2b2d037676a64b6f10b1e067bf7fa8b0bb7534a7c8bd2edcf80b1277903b0d7532cb1d3a17de56400236ea58
diff --git a/dev-python/authlib/authlib-1.6.6.ebuild b/dev-python/authlib/authlib-1.6.6.ebuild
new file mode 100644
index 000000000000..625edf4230ee
--- /dev/null
+++ b/dev-python/authlib/authlib-1.6.6.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517="setuptools"
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1
+
+DESCRIPTION="A Python library in building OAuth and OpenID Connect servers and clients"
+HOMEPAGE="
+	https://authlib.org/
+	https://github.com/authlib/authlib/
+	https://pypi.org/project/Authlib/
+"
+# pypi source distribution excludes the tests
+SRC_URI="
+	https://github.com/authlib/authlib/archive/refs/tags/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="django flask jose test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/cryptography[${PYTHON_USEDEP}]
+	django? (
+		dev-python/django[${PYTHON_USEDEP}]
+	)
+	flask? (
+		dev-python/flask[${PYTHON_USEDEP}]
+		dev-python/flask-sqlalchemy[${PYTHON_USEDEP}]
+	)
+	jose? (
+		>=dev-python/pycryptodome-3.10[${PYTHON_USEDEP}]
+	)
+"
+BDEPEND="
+	test? (
+		dev-python/anyio[${PYTHON_USEDEP}]
+		dev-python/cachelib[${PYTHON_USEDEP}]
+		dev-python/django[${PYTHON_USEDEP}]
+		dev-python/flask[${PYTHON_USEDEP}]
+		dev-python/flask-sqlalchemy[${PYTHON_USEDEP}]
+		dev-python/httpx[${PYTHON_USEDEP}]
+		>=dev-python/pycryptodome-3.10[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/starlette[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-asyncio )
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# convert from pycryptodomex to pycryptodome
+	sed -i -e 's:from Cryptodome:from Crypto:' \
+		authlib/jose/drafts/_jwe_enc_cryptodome.py || die
+}
+
+python_test() {
+	local -x DJANGO_SETTINGS_MODULE=tests.django_settings
+	epytest tests/{core,jose,clients,flask}
+
+	# TODO: django.core.exceptions.AppRegistryNotReady: Apps aren't loaded yet.
+	#epytest tests/django
+}