dev-libs/boehm-gc: add 8.2.10

Signed-off-by: Antonis Tatmichalis <antonistatmichalis@outlook.com>
Part-of: https://github.com/gentoo/gentoo/pull/44801
Closes: https://github.com/gentoo/gentoo/pull/44801
Signed-off-by: Sam James <sam@gentoo.org>

dev-libs/boehm-gc/Manifest

@@ -1 +1,2 @@
+DIST gc-8.2.10.tar.gz 1229219 BLAKE2B 2f3da8273fd2a4b54041ea1b82e19cf93a301e07cc9cfd6f72444c057fc8a0cdb470c97c46e91ee49ddc33c5156875f7984993c298b385b5382424e230be5d9b SHA512 56558bf81716caa882fd015f3f0d0d86d05f38680266b22798153b1e7f4a6fbbcded2efb3e125c41a4c52d44259ac4900061e61729663f62427e73b691e317b0
 DIST gc-8.2.8.tar.gz 1219553 BLAKE2B 7e0da4d9596b53bacb41a9939c0dfc9c8cf9b57c032dd445a74678b9467bc9253749497ad3f9ae43060aafed42877191b27c5e8faad1a59f75e80a68fa6d37bd SHA512 e0994bac8d1068f79a8379fa5797efbd420b22eb923d6537613e7542fc6805f74f57be0c4ff7555539461f8ace849fa1534e2077752bfb61c0e14f367b5b55af

dev-libs/boehm-gc/boehm-gc-8.2.10.ebuild

@@ -0,0 +1,63 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit dot-a multilib-minimal libtool
+
+MY_P="gc-${PV}"
+
+DESCRIPTION="The Boehm-Demers-Weiser conservative garbage collector"
+HOMEPAGE="https://www.hboehm.info/gc/ https://github.com/ivmai/bdwgc/"
+SRC_URI="https://github.com/ivmai/bdwgc/releases/download/v${PV}/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="boehm-gc"
+# SONAME: libgc.so.1 libgccpp.so.1
+# We've been using subslot 0 for these instead of "1.1".
+SLOT="0"
+# Don't keyword versions if upstream mark them as pre-release.
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+IUSE="cxx +large static-libs +threads"
+
+RDEPEND=">=dev-libs/libatomic_ops-7.4[${MULTILIB_USEDEP}]"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	default
+
+	# bug #594754
+	elibtoolize
+}
+
+src_configure() {
+	use static-libs && lto-guarantee-fat
+	multilib-minimal_src_configure
+}
+
+multilib_src_configure() {
+	local config=(
+		--disable-docs
+		--with-libatomic-ops
+		$(use_enable cxx cplusplus)
+		$(use_enable static-libs static)
+		$(use threads || echo --disable-threads)
+		$(use_enable large large-config)
+	)
+
+	ECONF_SOURCE="${S}" econf "${config[@]}"
+}
+
+multilib_src_install_all() {
+	local HTML_DOCS=( doc/*.md )
+	einstalldocs
+	dodoc doc/README{.environment,.linux,.macros}
+
+	# Package provides .pc files
+	find "${ED}" -name '*.la' -delete || die
+
+	newman doc/gc.man GC_malloc.1
+
+	strip-lto-bytecode
+}