diff --git a/dev-python/pythran/Manifest b/dev-python/pythran/Manifest
index 969f78d811c18..387bd3c2c3f9c 100644
--- a/dev-python/pythran/Manifest
+++ b/dev-python/pythran/Manifest
@@ -1,2 +1,3 @@
 DIST pythran-0.12.1.gh.tar.gz 3631063 BLAKE2B c680639a88cd63398f88ee6f5325da288c06549bfef2ee649e27dd92114a2690f54fb3da730c4eb30ff9b7ef297c219bafa5f7f7153b7710d348859a04716e84 SHA512 05c4e1d03de3eebccbb915e13c70a36de293152aece58066f2d91d483d3ac920d61c7a76adcb2337f60e637734451775f0fc61341b0ef9fc4f074a752e39de9d
+DIST pythran-0.12.2.gh.tar.gz 3631092 BLAKE2B 5c7c9aadd1351fbfd1368b2957ad5952338aaf41bc124caad4243538f325599d50eeda12383a41e2bff0245ab2ecda3a27254d98d3e09f929d3d28856d556cd3 SHA512 2f83a2cda04dbdf55dcb6f5f1f43e9bb39668fa9f568ed39760a360f59f65b1e7e1f313d26efcb530fad34e69cc8dfb5aa38747943daa8d06d00b2610a1a7be5
 DIST pythran-0.13.1.gh.tar.gz 3639196 BLAKE2B 8aba73c68542d69dd2287d7081226161ecade9e49fe6ea69d034f9116becbc148614212cbcff0056291809d2994caf43ee374393939e44635c6bed69220b29b8 SHA512 2497fa49d78ff64e577816f4b48bd424c03f04b7605c92d359f0f8514aaa67b30b7e68248db475c215deafaf7e55f7b4b74ab37c9dbef2a27e813878bf350e77
diff --git a/dev-python/pythran/pythran-0.12.2.ebuild b/dev-python/pythran/pythran-0.12.2.ebuild
new file mode 100644
index 0000000000000..ed7c02739d9ea
--- /dev/null
+++ b/dev-python/pythran/pythran-0.12.2.ebuild
@@ -0,0 +1,67 @@
+# Copyright 2021-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_TESTED=( python3_{9..11} )
+PYTHON_COMPAT=( "${PYTHON_TESTED[@]}" )
+
+inherit distutils-r1 multiprocessing
+
+MY_P=${P/_p/.post}
+DESCRIPTION="Ahead of Time compiler for numeric kernels"
+HOMEPAGE="
+	https://pypi.org/project/pythran/
+	https://github.com/serge-sans-paille/pythran/
+"
+SRC_URI="
+	https://github.com/serge-sans-paille/pythran/archive/${PV/_p/.post}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 arm arm64 ~ia64 ~loong ppc ppc64 ~riscv ~s390 ~sparc x86"
+
+RDEPEND="
+	dev-libs/boost
+	=dev-python/beniget-0.4*[${PYTHON_USEDEP}]
+	<dev-python/gast-0.5.4[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	>=dev-python/ply-3.4[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/ipython[${PYTHON_USEDEP}]
+		' "${PYTHON_TESTED[@]}")
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+		dev-python/wheel[${PYTHON_USEDEP}]
+		virtual/cblas
+		!!dev-python/setuptools-declarative-requirements
+	)
+"
+
+distutils_enable_tests pytest
+
+src_configure() {
+	# TODO: package xsimd then set no_xsimd = True
+	cat >> setup.cfg <<-EOF
+		[build_py]
+		no_boost = True
+	EOF
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO
+		pythran/tests/test_xdoc.py::TestDoctest::test_cli
+		pythran/tests/test_xdoc.py::TestDoctest::test_toolchain
+	)
+
+	local -x COLUMNS=80
+	epytest -n "$(makeopts_jobs)"
+}