From 5c64edecc431d4c42f6f290b9f087bbefc0a6184 Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Tue, 7 Jul 2026 21:09:40 +0200
Subject: [PATCH] dev-embedded/ponyprog: drop use of git-r3 reserved variable

Even in git master, this package continues to be locked on
<app-editors/qhexedit2-0.9.0 which does not support py3_14 in stable.

https://bugs.gentoo.org/978907
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 .../ponyprog-3.1.4_p20250501-r1.ebuild        | 47 +++++++++++++++++++
 1 file changed, 47 insertions(+)
 create mode 100644 dev-embedded/ponyprog/ponyprog-3.1.4_p20250501-r1.ebuild

diff --git a/dev-embedded/ponyprog/ponyprog-3.1.4_p20250501-r1.ebuild b/dev-embedded/ponyprog/ponyprog-3.1.4_p20250501-r1.ebuild
new file mode 100644
index 0000000000000..b6f34de9fa8a8
--- /dev/null
+++ b/dev-embedded/ponyprog/ponyprog-3.1.4_p20250501-r1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+COMMIT="5a4ef795b297ed1eaf6b4d4e71b3ce7a1bb63481"
+inherit cmake udev
+
+DESCRIPTION="EEPROM and microcontroller programmer/flasher"
+HOMEPAGE="https://github.com/lancos/ponyprog/"
+SRC_URI="https://github.com/lancos/${PN}/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-${COMMIT}"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="
+	>=app-editors/qhexedit2-0.8.10
+	<app-editors/qhexedit2-0.9.0
+	dev-embedded/libftdi:1[cxx]
+	dev-qt/qtbase:6[gui,widgets]
+	dev-qt/qtmultimedia:6
+	virtual/libusb:1
+"
+RDEPEND="${DEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-cyrillic.patch
+	"${FILESDIR}"/${P}-fix-build-system.patch
+	"${FILESDIR}"/${P}-usbwatcher-qt6.patch
+)
+
+pkg_postinst() {
+	udev_reload
+
+	elog "To use the COM port in user mode (not as root), you need to"
+	elog "be in the 'uucp' group."
+	elog
+	elog "To use the LPT port in user mode (not as root) you need a kernel with"
+	elog "ppdev, parport and parport_pc compiled in or as modules. You need the"
+	elog "rights to write to /dev/parport? devices."
+}
+
+pkg_postrm() {
+	udev_reload
+}