From 5bacc674b9b2e5e84ae4de798e1ea86fa72d4f70 Mon Sep 17 00:00:00 2001
From: Andrew Ammerlaan <andrewammerlaan@gentoo.org>
Date: Thu, 5 Aug 2021 09:40:40 +0200
Subject: [PATCH] dev-python/spyder: remove version 5.1.0

Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Andrew Ammerlaan <andrewammerlaan@gentoo.org>
---
 dev-python/spyder/Manifest            |   1 -
 dev-python/spyder/spyder-5.1.0.ebuild | 188 --------------------------
 2 files changed, 189 deletions(-)
 delete mode 100644 dev-python/spyder/spyder-5.1.0.ebuild

diff --git a/dev-python/spyder/Manifest b/dev-python/spyder/Manifest
index 9bb628691b36e..d7d6e1125337e 100644
--- a/dev-python/spyder/Manifest
+++ b/dev-python/spyder/Manifest
@@ -1,6 +1,5 @@
 DIST spyder-4.2.5.tar.gz 11539071 BLAKE2B 9d7a98da018aae934803d640995fe2dfa6bbb20bfc7140bd00f5e7a00a09c47922fefd8df84f4b217a50176ee190515da6f4cbf498a03cae68e2ac4f5ec70664 SHA512 081b047a45b7522a69b1b21a221ab5cdef47f87f36ed4423ff63297d205f924c1627517c50622acb2d10efa094bc506fed4ec88f861775d3f58e81ac6ef017ac
 DIST spyder-5.0.5.tar.gz 20606379 BLAKE2B 52f05ffcf0b6aabdac23a055af1c674c6aa80a7d4f3608779df1d46e0e51de63a71b4e97db286dc92e071cbb44a0dc827aa750d8ca538e6764b5e780f493d615 SHA512 17654ee76eb51c5f5b9f494d009af3d7813f869f27f22ceb8ad8ca96dcedcbcd6b86c7a3895bb63eba3cc60e4a57ab94128abb8d21f05c4672b8bb8d545fe1ff
-DIST spyder-5.1.0.tar.gz 19777581 BLAKE2B 88b485ebc59f6609b051522c0c28da3ad09956defc22ada3d8db7b4cad46b0dd7445617a92387855d490c3646f1099578a4e2c70deb939d0d5d24516341b10ae SHA512 5bf9a2935cdff4423f1bfa5baadcc6f2eb2a4caf41f1cdf44c02d39199e0a244a3ffbad76f14181f90a844a59df07ee760e5f4bf36cb5f7081b2167f63e88acb
 DIST spyder-5.1.1.tar.gz 19782262 BLAKE2B 64dcd45b91eba57cb5e435fe4b9d9c2f0884165e68099fa0a354ddfba13fc41022564218ad9661126c18f638dc5d26083494d0a97454e5a1055d01848df896fe SHA512 ba6ee6681ca2c3ae0b41aab57b28747d27141f274bb28331926ad75d9c5011cee604895f7b187853f5d7dc4777d4ca21a954911adb1b063dc1da26ff88cbfa2c
 DIST spyder-docs-5eb83118155a3765de4a0f863b936bcbe73bb7aa.tar.gz 85362596 BLAKE2B 7294dcd0f169958da132b141379b9b1cf497095981a86416fb98d98f98e30a425fe2e628a523785f932bbc06a2ba1ecddb45bae0df009887db928f879e08cdef SHA512 45f45546b83afb3036348e89ee3eded4d8ecee36ce58fe697da14677fbff8fa2dfe170be7385ecf10e1989817780c07b5676d545ee34e87a8f252929ad72882e
 DIST spyder-docs-78b25754c69a20643258821146e398ad5535c920.tar.gz 69167467 BLAKE2B d2815d552002f329b5fac59329fba3b3b0cd592bcbdacc0878966919e44dbab29548533661e60a1b9b8fd763d57d1e4c2f761782ace1b0a814a5f0cec1f66af9 SHA512 10764367fd5f830d7a3620b9d9e7ec4ab74539c1f48326c0c40f7caff74a50401addc7609fe1558c57dac4649d0a214c0d2d77cecd100bd8574151134e49634d
diff --git a/dev-python/spyder/spyder-5.1.0.ebuild b/dev-python/spyder/spyder-5.1.0.ebuild
deleted file mode 100644
index c5e55ea1d098a..0000000000000
--- a/dev-python/spyder/spyder-5.1.0.ebuild
+++ /dev/null
@@ -1,188 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-PYTHON_COMPAT=( python3_{8..9} )
-DISTUTILS_USE_SETUPTOOLS=rdepend
-
-inherit optfeature xdg distutils-r1
-
-# Commit of documentation to fetch
-DOCS_PV="ebf13f362a604c5ac127efcddb74a91610d92f59"
-
-DESCRIPTION="The Scientific Python Development Environment"
-HOMEPAGE="
-	https://www.spyder-ide.org/
-	https://github.com/spyder-ide/spyder/
-	https://pypi.org/project/spyder/
-"
-SRC_URI="
-	https://github.com/spyder-ide/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
-	https://github.com/spyder-ide/${PN}-docs/archive/${DOCS_PV}.tar.gz -> ${PN}-docs-${DOCS_PV}.tar.gz
-"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS=""
-
-# The test suite often hangs or does not work. Technically spyder requires
-# pyqt5<13, which we do not have in ::gentoo any more. Likely this is the reason
-# many of the tests fail or hang. RESTRICTing because IMO it is not worth the
-# several hours I spend every single version bump checking which tests do and
-# do not work. Spyder itself works fine with pyqt5>13.
-RESTRICT="test"
-
-RDEPEND="
-	>=dev-python/atomicwrites-1.2.0[${PYTHON_USEDEP}]
-	>=dev-python/chardet-2.0.0[${PYTHON_USEDEP}]
-	>=dev-util/cookiecutter-1.6.0[${PYTHON_USEDEP}]
-	>=dev-python/diff-match-patch-20181111[${PYTHON_USEDEP}]
-	>=dev-python/intervaltree-3.0.2[${PYTHON_USEDEP}]
-	>=dev-python/jsonschema-3.2.0[${PYTHON_USEDEP}]
-	>=dev-python/keyring-17.0.0[${PYTHON_USEDEP}]
-	>=dev-python/nbconvert-4.0[${PYTHON_USEDEP}]
-	>=dev-python/numpydoc-0.6.0[${PYTHON_USEDEP}]
-	>=dev-python/pexpect-4.4.0[${PYTHON_USEDEP}]
-	>=dev-python/pickleshare-0.4[${PYTHON_USEDEP}]
-	>=dev-python/psutil-5.3[${PYTHON_USEDEP}]
-	>=dev-python/pygments-2.0[${PYTHON_USEDEP}]
-	>=dev-python/python-lsp-black-1.0.0[${PYTHON_USEDEP}]
-	>=dev-python/pyls-spyder-0.4.0[${PYTHON_USEDEP}]
-	>=dev-python/pyxdg-0.26[${PYTHON_USEDEP}]
-	>=dev-python/pyzmq-17[${PYTHON_USEDEP}]
-	~dev-python/qdarkstyle-3.0.2[${PYTHON_USEDEP}]
-	>=dev-python/qstylizer-0.1.10[${PYTHON_USEDEP}]
-	>=dev-python/qtawesome-1.0.2[${PYTHON_USEDEP}]
-	>=dev-python/qtconsole-5.1.0[${PYTHON_USEDEP}]
-	>=dev-python/QtPy-1.5.0[${PYTHON_USEDEP},pyqt5(+),svg,webengine]
-	>=sci-libs/rtree-0.9.7[${PYTHON_USEDEP}]
-	>=dev-python/sphinx-0.6.6[${PYTHON_USEDEP}]
-	>=dev-python/spyder-kernels-2.1.0[${PYTHON_USEDEP}]
-	<dev-python/spyder-kernels-2.2.0[${PYTHON_USEDEP}]
-	>=dev-python/textdistance-4.2.0[${PYTHON_USEDEP}]
-	>=dev-python/three-merge-0.1.1[${PYTHON_USEDEP}]
-	>=dev-python/watchdog-0.10.3[${PYTHON_USEDEP}]
-"
-
-BDEPEND="
-	test? (
-		dev-python/cython[${PYTHON_USEDEP}]
-		dev-python/flaky[${PYTHON_USEDEP}]
-		dev-python/matplotlib[tk,${PYTHON_USEDEP}]
-		dev-python/pandas[${PYTHON_USEDEP}]
-		dev-python/pillow[${PYTHON_USEDEP}]
-		<dev-python/pytest-6.0[${PYTHON_USEDEP}]
-		dev-python/pytest-lazy-fixture[${PYTHON_USEDEP}]
-		dev-python/pytest-mock[${PYTHON_USEDEP}]
-		dev-python/pytest-ordering[${PYTHON_USEDEP}]
-		<dev-python/pytest-qt-4[${PYTHON_USEDEP}]
-		dev-python/pytest-xvfb[${PYTHON_USEDEP}]
-		dev-python/pyyaml[${PYTHON_USEDEP}]
-		dev-python/scipy[${PYTHON_USEDEP}]
-		dev-python/sympy[${PYTHON_USEDEP}]
-	)"
-
-# Based on the courtesy of Arfrever
-# This patch removes a call to update-desktop-database during build
-# This fails because access is denied to this command during build
-PATCHES=(
-	"${FILESDIR}/${PN}-5.0.0-build.patch"
-	"${FILESDIR}/${PN}-5.0.1-doc-theme-renamed.patch"
-)
-
-DOCS=(
-	"AUTHORS.txt"
-	"Announcements.md"
-	"CHANGELOG.md"
-	"CODE_OF_CONDUCT.md"
-	"CONTRIBUTING.md"
-	"NOTICE.txt"
-	"README.md"
-	"RELEASE.md"
-)
-
-distutils_enable_tests pytest
-distutils_enable_sphinx docs/doc \
-	dev-python/sphinx-panels \
-	dev-python/pydata-sphinx-theme \
-	dev-python/sphinx-multiversion
-
-python_prepare_all() {
-	# move docs into workdir
-	mv ../spyder-docs-${DOCS_PV}* docs || die
-
-	# these dependencies are packaged separately:
-	#    dev-python/spyder-kernels,
-	#    dev-python/python-language-server,
-	#    dev-python/qdarkstyle
-	rm -r external-deps/* || die
-	# runs against things packaged in external-deps dir
-	rm conftest.py || die
-
-	# Do not depend on pyqt5<5.13, this dependency is carried by QtPy[pyqt5]
-	# Do not depend on pyqtwebengine<5.13, this dependency is carried by QtPy[webengine]
-	# Do not depend on parso and jedi, this is dependency is carried in python-lsp-server
-	# Do not depend on python-lsp-server, this dependency is carried in pyls-spyder
-	# The explicit version requirements only make things more complicated, if e.g.
-	# pyls-spyder gains compatibility with a newer version of python-lsp-server
-	# in a new release it will take time for this information to propagate into
-	# the next spyder release. So just remove the dependency and let the other
-	# ebuilds handle the version requirements to speed things up and prevent
-	# issues such as Bug 803269.
-	sed -i \
-		-e '/pyqt5/d' \
-		-e '/pyqtwebengine/d' \
-		-e '/python-lsp-server/d' \
-		-e '/parso/d' \
-		-e '/jedi/d' \
-			{setup.py,requirements/conda.txt} || die
-	sed -i \
-		-e "/^PYLS_REQVER/c\PYLS_REQVER = '>=0.0.1'" \
-		-e "/^PYLSP_REQVER/c\PYLSP_REQVER = '>=0.0.1'" \
-		-e "/^PARSO_REQVER/c\PARSO_REQVER = '>=0.0.1'" \
-		-e "/^JEDI_REQVER/c\JEDI_REQVER = '>=0.0.1'" \
-			spyder/dependencies.py || die
-
-	# do not check deps, fails because we removed pyqt5 dependency above
-	sed -i -e 's:test_dependencies_for_spyder_setup_install_requires_in_sync:_&:' \
-		spyder/tests/test_dependencies_in_sync.py || die
-
-	# can't check for update, need network
-	rm spyder/workers/tests/test_update.py || die
-
-	# skip online test
-	rm spyder/widgets/github/tests/test_github_backend.py || die
-
-	distutils-r1_python_prepare_all
-}
-
-# Calling pytest directly makes the tests freeze after completing even if successful
-# Exit code is nonzero even upon success, so can't add || die here test results
-# should be checked for success manually
-python_test() {
-	"${EPYTHON}" runtests.py
-}
-
-pkg_postinst() {
-	xdg_pkg_postinst
-
-	optfeature "2D/3D plotting in the Python and IPython consoles" dev-python/matplotlib
-	optfeature "View and edit DataFrames and Series in the Variable Explorer" dev-python/pandas
-	optfeature "View and edit two or three dimensional arrays in the Variable Explorer" dev-python/numpy
-	optfeature "Symbolic mathematics in the IPython console" dev-python/sympy
-	optfeature "Import Matlab workspace files in the Variable Explorer" dev-python/scipy
-	optfeature "Run Cython files in the IPython console" dev-python/cython
-	optfeature "The hdf5/h5py plugin" dev-python/h5py
-	optfeature "The line profiler plugin" dev-python/spyder-line-profiler
-	optfeature "The memory profiler plugin" dev-python/spyder-memory-profiler
-	# spyder-autopep8 does not have a release (yet)
-	# and are not compatible with >=spyder-4.0.0 at the moment
-	# optfeature "The autopep8 plugin" dev-python/spyder-autopep8
-	optfeature "Vim key bindings" dev-python/spyder-vim
-	optfeature "Unittest support" dev-python/spyder-unittest
-	optfeature "Jupyter notebook support" dev-python/spyder-notebook
-	optfeature "System terminal inside spyder" dev-python/spyder-terminal
-	# spyder-reports not yet updated to >=spyder-4.0.0
-	# optfeature "Markdown reports using Pweave" dev-python/spyder-reports
-}