diff --git a/dev-python/calver/Manifest b/dev-python/calver/Manifest
new file mode 100644
index 0000000000000..5af01431b30ce
--- /dev/null
+++ b/dev-python/calver/Manifest
@@ -0,0 +1 @@
+DIST calver-2021.7.30.gh.tar.gz 7058 BLAKE2B 90cb8568bce2afcf3e086e038dc237440c5d20c05cc19b7d6966d16b55854810a627120dc870d77975676ca166eac0922443d19b85aeffdb51f3cf435848ef5d SHA512 17c10b0f60ec4c8c582de660bd715d054c3478d8fdec88a6830396bad1d6147ce375a34c5ff57d244c8c2e337a6b382b6ee10673182a40bc14ad16a97405f181
diff --git a/dev-python/calver/calver-2021.7.30.ebuild b/dev-python/calver/calver-2021.7.30.ebuild
new file mode 100644
index 0000000000000..ee5748e2277a3
--- /dev/null
+++ b/dev-python/calver/calver-2021.7.30.ebuild
@@ -0,0 +1,42 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3 python3_{8..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Setuptools extension for CalVer package versions"
+HOMEPAGE="
+	https://github.com/di/calver/
+	https://pypi.org/project/calver/
+"
+SRC_URI="
+	https://github.com/di/calver/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+BDEPEND="
+	test? (
+		dev-python/pretend[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# bootstrap workaround, until https://github.com/di/calver/pull/8
+	# is merged
+	cat > setup.cfg <<-EOF
+		[metadata]
+		version = ${PV}
+	EOF
+}
diff --git a/dev-python/calver/metadata.xml b/dev-python/calver/metadata.xml
new file mode 100644
index 0000000000000..2acd1a33af2ca
--- /dev/null
+++ b/dev-python/calver/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">di/calver</remote-id>
+		<remote-id type="pypi">calver</remote-id>
+	</upstream>
+</pkgmetadata>