app-office/texstudio: drop 4.8.7

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

app-office/texstudio/Manifest

@@ -1,2 +1 @@
-DIST texstudio-4.8.7.tar.gz 114210486 BLAKE2B 6a66efada3056e3c731cd0461c9b44ec73f41e61580ad2267757f90ad974ab33499b34ca89c59ff5698a641a72ae4d4fc797b27711d17b161c239481185d493b SHA512 bdfc59b3c08d6ff15eb00184455f4b5e2cfb353e2624c28363f525d2d31ebf7c741aa0a9ae3236a07cb910bc93db2460c3191e6c6e66b4e6da24e40396151e23
 DIST texstudio-4.8.9.tar.gz 115097229 BLAKE2B 3aadc08b827279fbfad67f4e4e2cdc7e1492747e6b4f1667cf566695fda60870e44b5f3c342aaafbab0311278bd95c080cc1392e0bb6c05e3475ee132efc8f28 SHA512 b552e36bf489ac974311e06173f2779cb640d16b88f923d73ff910cc7533b7c4c3374fd7a37e56cc03de3bf8a035e71708f11e14584c880c128505169fca51f7

app-office/texstudio/texstudio-4.8.7.ebuild

@@ -1,90 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit cmake desktop optfeature xdg
-
-DESCRIPTION="Free cross-platform LaTeX editor (fork from texmakerX)"
-HOMEPAGE="https://www.texstudio.org https://github.com/texstudio-org/texstudio"
-SRC_URI="https://github.com/texstudio-org/texstudio/archive/${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="amd64 ~arm ~arm64 ~ppc ~ppc64 x86"
-
-IUSE="video"
-
-DEPEND="
-	app-text/hunspell:=
-	app-text/poppler:=[qt6]
-	dev-libs/quazip:0=[qt6]
-	dev-qt/qt5compat:6
-	dev-qt/qtbase:6[concurrent,gui,network,widgets,xml]
-	dev-qt/qtdeclarative:6
-	dev-qt/qtsvg:6
-	dev-qt/qttools:6[widgets]
-	virtual/zlib:=
-	x11-libs/libX11
-	video? ( dev-qt/qtmultimedia:6 )
-"
-RDEPEND="
-	${DEPEND}
-	virtual/latex-base
-"
-BDEPEND="
-	dev-qt/qttools:6[linguist]
-	virtual/pkgconfig
-"
-
-src_prepare() {
-	local dir
-	for dir in src/quazip src/hunspell utilities/poppler-data; do
-		rm -r "${dir}" || die "Failed to delete ${dir}"
-	done
-
-	# https://bugs.gentoo.org/940747
-	sed -i 's/Qt5 //' CMakeLists.txt || die
-
-	cmake_src_prepare
-}
-
-src_configure() {
-	local mycmakeargs=(
-		-DQT_VERSION_MAJOR=6
-		# already exists in ::gentoo, useful only for win
-		-DTEXSTUDIO_BUILD_ADWAITA=NO
-		-DTEXSTUDIO_ENABLE_MEDIAPLAYER=$(usex video)
-		# it requires debug and make changes in the UI
-		# see #940928
-		-DTEXSTUDIO_ENABLE_TESTS=NO
-	)
-	cmake_src_configure
-}
-
-src_install() {
-	# manually set docdir to use a subdir for html
-	# and avoid the path /usr/share/doc/texstudio
-	local DOCS+=( utilities/{AUTHORS,COPYING,manual/source/CHANGELOG.md} )
-	local HTML_DOCS+=( utilities/*.{html,css} utilities/manual/build/html/. )
-	cmake_src_install
-
-	# remove the wrong path
-	rm -r "${ED}"/usr/share/doc/texstudio || die
-
-	local i
-	for i in 16x16 22x22 32x32 48x48 64x64 128x128; do
-		newicon -s ${i} utilities/${PN}${i}.png ${PN}.png
-	done
-}
-
-pkg_postinst() {
-	xdg_pkg_postinst
-
-	optfeature "conversion tools" app-text/ghostscript-gpl
-	optfeature "PostScript tools" app-text/psutils
-	optfeature "graphic tools" media-libs/netpbm
-	optfeature "automation" dev-tex/latexmk
-	optfeature "XeLaTex engine" dev-texlive/texlive-xetex
-	optfeature "the vector graphics language (.asy)" media-gfx/asymptote
-}