diff --git a/app-crypt/gcr/Manifest b/app-crypt/gcr/Manifest
index 63eb62972bd57..0c443c55790f8 100644
--- a/app-crypt/gcr/Manifest
+++ b/app-crypt/gcr/Manifest
@@ -2,3 +2,4 @@ DIST gcr-3.41.1.tar.xz 1030368 BLAKE2B 9d254b7f2ad864c45200e58b685db97c1ffbc83d2
 DIST gcr-3.41.2.tar.xz 1034532 BLAKE2B ac2c1cd7c1ff458b554a4c0b667fa9a6a9629f14ad173ec84e3bb76b17fefe007a47ed861fc820cb1a4f48b81b3dfe9860d521fe677c7dbcce004766b43afe9a SHA512 056c6c6a3910dae6997cef34fc95d22510ddea37be0ccc329996575a95e20582fa428bd491389aa77f8b6ffbd8674a2b3ba444cb83bdf3a2be5fd7aed276606d
 DIST gcr-4.2.1.tar.xz 719392 BLAKE2B a9134258f6daa59de4924f6bac01499d3bf87aae5e9d9ff5c69b2289ba0e82ef4c3f93a1ca7b1b007815e51e0c56f10a8abc616b31518dfa83581e8ffc5b3309 SHA512 fbb1664f6e276e35296aec46dab53ff308d031cae2f25b7d1ff5abdb56c5bd3764927d38b997d2ccbd260975f445d71619b2487327786c30b5f34d5e8865ff25
 DIST gcr-4.3.0.tar.xz 726488 BLAKE2B 9981c6d6cf1b4d7d83b1771439a2fab84360e6a1ab28d73dcbd4d6aab831e1fb69a10d3e073f8735c4842f58f2b4e189fd624b78d3007867cfc7fda767e1d15f SHA512 3f252de55e07d47a49c03b714e323ceb00d82e010fe1bb606073e3188bf8bef84359a322ed6fe843620fa5d108e825dd7e9a60136c8a0e802b8f2178aa87b164
+DIST gcr-4.3.1.tar.xz 729260 BLAKE2B d77db7fac539a422f974280e5d50d84a2f26ae735b9c5a73ccdd2f938dec6f4db6fd63a3a6dca21a6531d3998a472fbc5ea444ef22332b459413069b9a72597a SHA512 b9cd118493a9999a5e8795253b47762d567ffe763c6aa9fd441f44391003ee6e880fa6b67451c5e32905a2c5b07f7f4755ff19c43d8379ee863f3f9b978087b9
diff --git a/app-crypt/gcr/gcr-4.3.1.ebuild b/app-crypt/gcr/gcr-4.3.1.ebuild
new file mode 100644
index 0000000000000..20c2d3eddc066
--- /dev/null
+++ b/app-crypt/gcr/gcr-4.3.1.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic gnome.org gnome2-utils meson vala xdg
+
+DESCRIPTION="Libraries for cryptographic UIs and accessing PKCS#11 modules"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gcr"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="4/gcr-4.4-gck-2.2" # subslot = soname and soversion of libgcr and libgck
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+
+IUSE="gnutls gtk gtk-doc +introspection systemd test +vala"
+REQUIRED_USE="
+	gtk-doc? ( introspection )
+	vala? ( introspection )
+"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	>=dev-libs/glib-2.68.0:2
+	!gnutls? ( >=dev-libs/libgcrypt-1.2.2:0= )
+	gnutls? ( >=net-libs/gnutls-3.8.5:0 )
+	>=app-crypt/p11-kit-0.19.0
+	>=app-crypt/libsecret-0.20
+	systemd? ( sys-apps/systemd:= )
+	gtk? ( gui-libs/gtk:4[introspection?] )
+	>=sys-apps/dbus-1
+	introspection? ( >=dev-libs/gobject-introspection-1.58:= )
+	!<app-crypt/gcr-3.41.1-r1
+"
+RDEPEND="${DEPEND}"
+PDEPEND="app-crypt/gnupg"
+BDEPEND="
+	gtk? ( dev-libs/libxml2:2 )
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	gtk-doc? ( dev-util/gi-docgen )
+	>=sys-devel/gettext-0.19.8
+	test? ( app-crypt/gnupg )
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	default
+	use vala && vala_setup
+	xdg_environment_reset
+}
+
+src_configure() {
+	filter-lto # https://gitlab.gnome.org/GNOME/gcr/-/issues/43
+	local emesonargs=(
+		$(meson_use introspection)
+		$(meson_use gtk gtk4)
+		$(meson_use gtk-doc gtk_doc)
+		-Dgpg_path="${EPREFIX}"/usr/bin/gpg
+		-Dssh_agent=true
+		$(meson_feature systemd)
+		$(meson_use vala vapi)
+	)
+	if use gnutls; then
+		emesonargs+=( -Dcrypto=gnutls )
+	else
+		emesonargs+=( -Dcrypto=libgcrypt )
+	fi
+	meson_src_configure
+}
+
+src_test() {
+	dbus-run-session meson test -C "${BUILD_DIR}" || die 'tests failed'
+}
+
+src_install() {
+	meson_src_install
+
+	if use gtk-doc; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
+		mv "${ED}"/usr/share/doc/{gck-2,gcr-4} "${ED}"/usr/share/gtk-doc/html/ || die
+	fi
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}