From 577eb53df4b1fe99f809579b18287135634a8b8e Mon Sep 17 00:00:00 2001
From: James Le Cuirot <chewi@gentoo.org>
Date: Wed, 9 Jul 2025 16:24:59 +0100
Subject: [PATCH] gui-apps/input-leap: Version bump to 3.0.3

Signed-off-by: James Le Cuirot <chewi@gentoo.org>
---
 gui-apps/input-leap/Manifest                |  1 +
 gui-apps/input-leap/input-leap-3.0.3.ebuild | 87 +++++++++++++++++++++
 gui-apps/input-leap/input-leap-9999.ebuild  |  2 +-
 3 files changed, 89 insertions(+), 1 deletion(-)
 create mode 100644 gui-apps/input-leap/input-leap-3.0.3.ebuild

diff --git a/gui-apps/input-leap/Manifest b/gui-apps/input-leap/Manifest
index d0a806e487e54..94bfb2234afaf 100644
--- a/gui-apps/input-leap/Manifest
+++ b/gui-apps/input-leap/Manifest
@@ -1,2 +1,3 @@
 DIST input-leap-3.0.2-no-x11.patch 167137 BLAKE2B 850d4e842233a960136251ff83cbfa58cddd73f15da84d6f024ebcb08b0b7bcafc8cd3d402e5b2297f68b4ab75ff47e241e1c8d32f900babec496c7a39906bed SHA512 d80fd984d26f1cd141a2635b35740a320c389dd60b651a6d4c8ef4db04778cb7c090ddd5aee2d8061cc69fe4d58b36262008bcce5cab05ce84162af699e086c7
 DIST input-leap-3.0.2.tar.gz 1764599 BLAKE2B 0924a1869b1820710b426e68a45e1e538c15a656677d0d2459697035ff1780c12f07da05ecb3890595833ac4ad6e07c66cc68164fa8d70f259b1599d0b287c1e SHA512 caadf17b64765c0732e94e6a38e17e560d050a2fa0252f26ec382f3f80af936aa9d0aa8172e29724b04223fd3b378b68b7afe7db41c336431b839331815774d9
+DIST input-leap-3.0.3.tar.gz 1764202 BLAKE2B fbafa19481025660fba282580054fd0b9dc4d87553fcf495acfa15b0283e4f60fa15a904ba3ef516a8325aa3e99118aaf95343e741df5b57da30b958612f7965 SHA512 bcfad3938c2a6082ca3d2e083147002f0b870e81026580cc7f655ea9c43b707552e188a0fb93669466d037569e89983b35e16a272cb313e40039f2abac98f444
diff --git a/gui-apps/input-leap/input-leap-3.0.3.ebuild b/gui-apps/input-leap/input-leap-3.0.3.ebuild
new file mode 100644
index 0000000000000..c1b24c0fa8eb8
--- /dev/null
+++ b/gui-apps/input-leap/input-leap-3.0.3.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+VIRTUALX_REQUIRED="manual"
+inherit cmake virtualx xdg
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/input-leap/input-leap.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/input-leap/input-leap/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Share a mouse and keyboard between computers (fork of Barrier)"
+HOMEPAGE="https://github.com/input-leap/input-leap"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="gui test +wayland +X"
+REQUIRED_USE="|| ( wayland X )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/openssl:0=
+	gui? (
+		dev-qt/qtbase:6[gui,network,widgets]
+		net-dns/avahi[mdnsresponder-compat]
+	)
+	wayland? (
+		dev-libs/glib:2
+		dev-libs/libei
+		dev-libs/libportal:=
+		x11-libs/libxkbcommon
+	)
+	X? (
+		x11-libs/libICE
+		x11-libs/libSM
+		x11-libs/libX11
+		x11-libs/libXext
+		x11-libs/libXi
+		x11-libs/libXinerama
+		x11-libs/libXrandr
+		x11-libs/libXtst
+	)
+"
+DEPEND="
+	${RDEPEND}
+	x11-base/xorg-proto
+	test? ( dev-cpp/gtest )
+"
+BDEPEND="
+	virtual/pkgconfig
+	gui? ( dev-qt/qttools:6[linguist] )
+	test? ( X? ( ${VIRTUALX_DEPEND} ) )
+"
+
+DOCS=(
+	ChangeLog
+	README.md
+	doc/${PN}.conf.example{,-advanced,-basic}
+)
+
+src_configure() {
+	local REV="${EGIT_VERSION:-00000000}"
+	local mycmakeargs=(
+		-DINPUTLEAP_BUILD_GUI=$(usex gui)
+		-DINPUTLEAP_BUILD_LIBEI=$(usex wayland)
+		-DINPUTLEAP_BUILD_TESTS=$(usex test)
+		-DINPUTLEAP_BUILD_X11=$(usex X)
+		-DINPUTLEAP_REVISION="${REV:0:8}"
+		-DINPUTLEAP_USE_EXTERNAL_GTEST=ON
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	"${BUILD_DIR}"/bin/unittests || die
+
+	if use X; then
+		virtx "${BUILD_DIR}"/bin/integtests
+	else
+		"${BUILD_DIR}"/bin/integtests || die
+	fi
+}
diff --git a/gui-apps/input-leap/input-leap-9999.ebuild b/gui-apps/input-leap/input-leap-9999.ebuild
index 1dc699561578e..c1b24c0fa8eb8 100644
--- a/gui-apps/input-leap/input-leap-9999.ebuild
+++ b/gui-apps/input-leap/input-leap-9999.ebuild
@@ -11,7 +11,7 @@ if [[ ${PV} == *9999* ]]; then
 	inherit git-r3
 else
 	SRC_URI="https://github.com/input-leap/input-leap/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
-	KEYWORDS="~amd64"
+	KEYWORDS="~amd64 ~x86"
 fi
 
 DESCRIPTION="Share a mouse and keyboard between computers (fork of Barrier)"