From 56f3f310a8ee9bde7b866ce93c6fc8cdedc74aa6 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Sun, 16 Nov 2025 04:37:18 +0100
Subject: [PATCH] dev-python/pythran: Bump to 0.18.1
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/pythran/Manifest              |  1 +
 dev-python/pythran/pythran-0.18.1.ebuild | 93 ++++++++++++++++++++++++
 2 files changed, 94 insertions(+)
 create mode 100644 dev-python/pythran/pythran-0.18.1.ebuild

diff --git a/dev-python/pythran/Manifest b/dev-python/pythran/Manifest
index e02bc31d9496..3d1629f0e818 100644
--- a/dev-python/pythran/Manifest
+++ b/dev-python/pythran/Manifest
@@ -1,2 +1,3 @@
 DIST pythran-0.17.0.gh.tar.gz 3697173 BLAKE2B 90f765283e4346392eb69d8e6fadf4b00469779bd7fb8dc99084ed0d2d940a1ca949c9dd0eb0fc484c2938de79b1e3650c417dc1cd30786b25b6781c519a629d SHA512 af14cd497bcbef7ac97b42b80e297e641bd520f51938b04a68ebf01de86d6900926653c01ff99b1af7f699674094241099101f1501acfae2be5dc9d1724af777
 DIST pythran-0.18.0.gh.tar.gz 3707538 BLAKE2B e2781e3e01677a3373fe7ffb87e9ef99ab2caba89ded3b15677aff963b967670687b5ff5206d3eb0a57332fb2848f67d077f8d3584d38a845a6657f29de28bc5 SHA512 70761b08724264ab048d6943b143123d19d81b65d3a5ab9aa023dc7d989bc51b33e17f9bb81a6e8f25f7bde4745f36d1208c8c2bd49f8d27b7a4776611f310a5
+DIST pythran-0.18.1.gh.tar.gz 3714257 BLAKE2B 711f271297a6012a88a696df749efda8ca4c53e236a646bf2285ba80d0151b1117492c024eb8ab2e5f7337b1f9838332dba480a00a9c2a9216cbbeda78f971a8 SHA512 15650627b9396b49401067c3a7c161d1569f89f29a08243aa85659023e42ce028633915c51c8c5188a5599c201eb30aa2721d64ba766b2a252203469bc6e2ab1
diff --git a/dev-python/pythran/pythran-0.18.1.ebuild b/dev-python/pythran/pythran-0.18.1.ebuild
new file mode 100644
index 000000000000..8e148563add0
--- /dev/null
+++ b/dev-python/pythran/pythran-0.18.1.ebuild
@@ -0,0 +1,93 @@
+# Copyright 2021-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3_11 python3_{11..14} )
+
+inherit distutils-r1
+
+MY_P=${P/_p/.post}
+DESCRIPTION="Ahead of Time compiler for numeric kernels"
+HOMEPAGE="
+	https://pypi.org/project/pythran/
+	https://github.com/serge-sans-paille/pythran/
+"
+SRC_URI="
+	https://github.com/serge-sans-paille/pythran/archive/${PV/_p/.post}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-libs/boost
+	dev-cpp/xsimd
+	=dev-python/beniget-0.4*[${PYTHON_USEDEP}]
+	=dev-python/gast-0.6*[${PYTHON_USEDEP}]
+	dev-python/numpy:=[${PYTHON_USEDEP}]
+	>=dev-python/ply-3.4[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-73.0.1[${PYTHON_USEDEP}]
+"
+DEPEND="
+	test? (
+		dev-libs/boost
+		dev-cpp/xsimd
+	)
+"
+BDEPEND="
+	test? (
+		dev-python/ipython[${PYTHON_USEDEP}]
+		dev-python/pip[${PYTHON_USEDEP}]
+		dev-python/packaging[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+		dev-python/wheel[${PYTHON_USEDEP}]
+		virtual/cblas
+		!!dev-python/setuptools-declarative-requirements
+	)
+"
+
+EPYTEST_PLUGINS=()
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_configure() {
+	# vendored C++ headers -- use system copies
+	rm -r pythran/{boost,xsimd} || die
+
+	# https://bugs.gentoo.org/916461
+	sed -i \
+		-e 's|blas=blas|blas=cblas|' \
+		-e 's|libs=|libs=cblas|' \
+		pythran/pythran-*.cfg || die
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# multiple extra deps (meson, openblas)
+		# also broken on pypy3*
+		pythran/tests/test_distutils.py::TestMeson::test_meson_build
+	)
+	local EPYTEST_IGNORE=(
+		pythran/benchmarks
+	)
+
+	case ${ARCH} in
+		arm)
+			EPYTEST_DESELECT+=(
+				# TODO
+				pythran/tests/test_numpy_fft.py::TestNumpyFFT::test_fft_3d_axis
+				pythran/tests/test_numpy_fft.py::TestNumpyFFTN
+			)
+			;;
+	esac
+
+	# can easily fill up ccache with no real benefit
+	local -x CCACHE_DISABLE=1
+	local -x COLUMNS=80
+	epytest
+}