gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-08-06 12:58:16 -07:00
Code Issues Projects Releases Wiki Activity

proj/gentoo: Initial commit

Browse Source 
This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed
This commit is contained in:
Robin H. Johnson
2015-08-08 13:49:04 -07:00
commit 56bd759df1
97532 changed files with 3536859 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/pandas/Manifest Normal file
View File

@@ -0,0 +1 @@
DIST pandas-0.16.2.tar.gz 4931751 SHA256 e01853dfe111f3aea005315573400b7216ddbabbf1f28d482a71217d67ae4f81 SHA512 44874e12a42a01dd7ed88f3f97e954732a534a5e2dc4815ef6203bdb2d88850a607e6631a35ae8fc79f4621a5dfaa34f39bb1c9a0ecfb17da1cf0c10f35ff27b WHIRLPOOL 6f2874ac07b49f4b2aaefdb87375b7c5adb31e3ff60c6b808f3e3467ad82999dd894de884ebbfd64fc7235e875d17ce871b516c96ff71a17310b708597168702

21
dev-python/pandas/metadata.xml Normal file
View File

@@ -0,0 +1,21 @@
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<herd>sci</herd>
<longdescription lang="en">
Pandas is a Python package providing fast, flexible, and expressive
data structures designed to make working with "relational" or
"labeled" data both easy and intuitive. It aims to be the
fundamental high-level building block for doing practical, real
world data analysis in Python.
</longdescription>
<use>
<flag name="excel">Pull a few Python packages for Microsoft Excel i/o</flag>
<flag name="html">Enable HTML i/o via <pkg>dev-python/beautifulsoup</pkg></flag>
<flag name="R">Enable support for R via <pkg>dev-python/rpy</pkg></flag>
</use>
<upstream>
<remote-id type="pypi">pandas</remote-id>
<remote-id type="github">pydata/pandas</remote-id>
</upstream>
</pkgmetadata>

128
dev-python/pandas/pandas-0.16.2.ebuild Normal file
View File

@@ -0,0 +1,128 @@
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=5
PYTHON_COMPAT=( python2_7 python3_{3,4} )
inherit distutils-r1 eutils flag-o-matic virtualx
DESCRIPTION="Powerful data structures for data analysis and statistics"
HOMEPAGE="http://pandas.pydata.org/"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
SLOT="0"
LICENSE="BSD"
KEYWORDS="amd64 x86 ~amd64-linux ~x86-linux"
IUSE="doc excel html test R"
EXTRA_DEPEND="
>=dev-python/google-api-python-client-1.2.0[$(python_gen_usedep python2_7 pypy)]
dev-python/openpyxl[${PYTHON_USEDEP}]
dev-python/pymysql[${PYTHON_USEDEP}]
dev-python/python-gflags[$(python_gen_usedep python2_7 pypy)]
dev-python/psycopg:2[${PYTHON_USEDEP}]
dev-python/statsmodels[${PYTHON_USEDEP}]
dev-python/sqlalchemy[${PYTHON_USEDEP}]
"
CDEPEND="
>dev-python/numpy-1.7[${PYTHON_USEDEP}]
>=dev-python/python-dateutil-2.0[${PYTHON_USEDEP}]
!~dev-python/openpyxl-1.9.0[${PYTHON_USEDEP}]"
DEPEND="${CDEPEND}
>=dev-python/cython-0.19.1[${PYTHON_USEDEP}]
doc? (
dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
dev-python/ipython[${PYTHON_USEDEP}]
dev-python/html5lib[${PYTHON_USEDEP}]
dev-python/lxml[${PYTHON_USEDEP}]
dev-python/matplotlib[${PYTHON_USEDEP}]
>=dev-python/openpyxl-1.6.1[${PYTHON_USEDEP}]
dev-python/openpyxl[${PYTHON_USEDEP}]
>=dev-python/pytables-3.0.0[${PYTHON_USEDEP}]
dev-python/pytz[${PYTHON_USEDEP}]
dev-python/rpy[${PYTHON_USEDEP}]
sci-libs/scipy[${PYTHON_USEDEP}]
>=dev-python/sphinx-1.2.1[${PYTHON_USEDEP}]
dev-python/xlrd[$(python_gen_usedep 'python2_7')]
dev-python/xlwt[$(python_gen_usedep 'python2_7')]
x11-misc/xclip
)
test? (
${EXTRA_DEPEND}
dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
dev-python/nose[${PYTHON_USEDEP}]
x11-misc/xclip
x11-misc/xsel
)"
# dev-python/statsmodels invokes a circular dep
# hence rm from doc? ( ), again
RDEPEND="${CDEPEND}
>=dev-python/numexpr-2.1[${PYTHON_USEDEP}]
dev-python/bottleneck[${PYTHON_USEDEP}]
dev-python/matplotlib[${PYTHON_USEDEP}]
dev-python/pytables[${PYTHON_USEDEP}]
dev-python/pytz[${PYTHON_USEDEP}]
sci-libs/scipy[${PYTHON_USEDEP}]
excel? (
dev-python/xlrd[$(python_gen_usedep 'python2_7')]
dev-python/xlwt[$(python_gen_usedep 'python2_7')]
|| (
dev-python/xlsxwriter[${PYTHON_USEDEP}]
>=dev-python/openpyxl-1.6.1[${PYTHON_USEDEP}]
)
)
html? (
dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
|| (
dev-python/lxml[${PYTHON_USEDEP}]
dev-python/html5lib[${PYTHON_USEDEP}] )
)
R? ( dev-python/rpy[${PYTHON_USEDEP}] )"
python_prepare_all() {
# Prevent un-needed download during build
sed -e "/^ 'sphinx.ext.intersphinx',/d" -i doc/source/conf.py || die
distutils-r1_python_prepare_all
}
python_compile_all() {
# To build docs the need be located in $BUILD_DIR,
# else PYTHONPATH points to unusable modules.
if use doc; then
cd "${BUILD_DIR}"/lib || die
cp -ar "${S}"/doc . && cd doc || die
LANG=C PYTHONPATH=. "${EPYTHON}" make.py html || die
fi
}
python_test() {
local test_pandas='not network and not disabled'
[[ -n "${FAST_PANDAS}" ]] && test_pandas+=' and not slow'
pushd "${BUILD_DIR}"/lib > /dev/null
VIRTUALX_COMMAND="nosetests"
PYTHONPATH=. MPLCONFIGDIR=. HOME=. \
virtualmake --verbosity=3 -A "${test_pandas}" pandas
popd > /dev/null
}
python_install_all() {
if use doc; then
dodoc -r "${BUILD_DIR}"/lib/doc/build/html
einfo "An initial build of docs is absent of references to statsmodels"
einfo "due to circular dependency. To have them included, emerge"
einfo "statsmodels next and re-emerge pandas with USE doc"
fi
distutils-r1_python_install_all
}
pkg_postinst() {
local x
elog "Please install"
for x in ${EXTRA_DEPEND}; do
optfeature "additional functionality" "${x%%[*}"
done
}

126
dev-python/pandas/pandas-9999.ebuild Normal file
View File

@@ -0,0 +1,126 @@
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=5
PYTHON_COMPAT=( python2_7 python3_{3,4} )
inherit distutils-r1 eutils flag-o-matic git-r3 virtualx
DESCRIPTION="Powerful data structures for data analysis and statistics"
HOMEPAGE="http://pandas.pydata.org/"
SRC_URI=""
EGIT_REPO_URI="https://github.com/pydata/pandas.git"
SLOT="0"
LICENSE="BSD"
KEYWORDS=""
IUSE="doc excel html test R"
EXTRA_DEPEND="
>=dev-python/google-api-python-client-1.2.0[$(python_gen_usedep python2_7 pypy)]
dev-python/openpyxl[${PYTHON_USEDEP}]
dev-python/pymysql[${PYTHON_USEDEP}]
dev-python/python-gflags[$(python_gen_usedep python2_7 pypy)]
dev-python/psycopg:2[${PYTHON_USEDEP}]
dev-python/statsmodels[${PYTHON_USEDEP}]
dev-python/sqlalchemy[${PYTHON_USEDEP}]
dev-python/xlsxwriter[${PYTHON_USEDEP}]
"
CDEPEND="
>dev-python/numpy-1.7[${PYTHON_USEDEP}]
>=dev-python/python-dateutil-2.0[${PYTHON_USEDEP}]
!~dev-python/openpyxl-1.9.0[${PYTHON_USEDEP}]"
DEPEND="${CDEPEND}
doc? (
dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
dev-python/ipython[${PYTHON_USEDEP}]
dev-python/html5lib[${PYTHON_USEDEP}]
dev-python/lxml[${PYTHON_USEDEP}]
dev-python/matplotlib[${PYTHON_USEDEP}]
>=dev-python/openpyxl-1.6.1[${PYTHON_USEDEP}]
dev-python/openpyxl[${PYTHON_USEDEP}]
>=dev-python/pytables-3.0.0[${PYTHON_USEDEP}]
dev-python/pytz[${PYTHON_USEDEP}]
dev-python/rpy[${PYTHON_USEDEP}]
sci-libs/scipy[${PYTHON_USEDEP}]
>=dev-python/sphinx-1.2.1[${PYTHON_USEDEP}]
dev-python/xlrd[$(python_gen_usedep 'python2_7')]
dev-python/xlwt[$(python_gen_usedep 'python2_7')]
x11-misc/xclip
)
test? (
${EXTRA_DEPEND}
dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
dev-python/nose[${PYTHON_USEDEP}]
x11-misc/xclip
x11-misc/xsel
)"
# dev-python/statsmodels invokes a circular dep
# hence rm from doc? ( ), again
RDEPEND="${CDEPEND}
>=dev-python/numexpr-2.1[${PYTHON_USEDEP}]
dev-python/bottleneck[${PYTHON_USEDEP}]
dev-python/matplotlib[${PYTHON_USEDEP}]
dev-python/pytables[${PYTHON_USEDEP}]
dev-python/pytz[${PYTHON_USEDEP}]
sci-libs/scipy[${PYTHON_USEDEP}]
excel? (
>=dev-python/openpyxl-1.6.1[${PYTHON_USEDEP}]
dev-python/xlrd[$(python_gen_usedep 'python2_7')]
dev-python/xlwt[$(python_gen_usedep 'python2_7')]
)
html? (
dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
|| (
dev-python/lxml[${PYTHON_USEDEP}]
dev-python/html5lib[${PYTHON_USEDEP}] )
)
R? ( dev-python/rpy[${PYTHON_USEDEP}] )"
python_prepare_all() {
# Prevent un-needed download during build
sed -e "/^ 'sphinx.ext.intersphinx',/d" -i doc/source/conf.py || die
distutils-r1_python_prepare_all
}
python_compile_all() {
# To build docs the need be located in $BUILD_DIR,
# else PYTHONPATH points to unusable modules.
if use doc; then
cd "${BUILD_DIR}"/lib || die
cp -ar "${S}"/doc . && cd doc || die
LANG=C PYTHONPATH=. "${EPYTHON}" make.py html || die
fi
}
python_test() {
local test_pandas='not network and not disabled'
[[ -n "${FAST_PANDAS}" ]] && test_pandas+=' and not slow'
pushd "${BUILD_DIR}"/lib > /dev/null
VIRTUALX_COMMAND="nosetests"
PYTHONPATH=. MPLCONFIGDIR=. HOME=. \
virtualmake --verbosity=3 -A "${test_pandas}" pandas
popd > /dev/null
}
python_install_all() {
if use doc; then
dodoc -r "${BUILD_DIR}"/lib/doc/build/html
einfo "An initial build of docs is absent of references to statsmodels"
einfo "due to circular dependency. To have them included, emerge"
einfo "statsmodels next and re-emerge pandas with USE doc"
fi
distutils-r1_python_install_all
}
pkg_postinst() {
local x
elog "Please install"
for x in ${EXTRA_DEPEND}; do
optfeature "additional functionality" "${x%%[*}"
done
}