From 567f65a2cad932277c607715c25f80ea94f2db5d Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Sun, 20 Sep 2026 03:35:02 +0200
Subject: [PATCH] dev-python/tox: Bump to 4.63.0
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/tox/Manifest          |  2 +
 dev-python/tox/tox-4.63.0.ebuild | 84 ++++++++++++++++++++++++++++++++
 2 files changed, 86 insertions(+)
 create mode 100644 dev-python/tox/tox-4.63.0.ebuild

diff --git a/dev-python/tox/Manifest b/dev-python/tox/Manifest
index dbb87a1f5b044..b69bfe3b2ae6d 100644
--- a/dev-python/tox/Manifest
+++ b/dev-python/tox/Manifest
@@ -14,3 +14,5 @@ DIST tox-4.61.5.tar.gz 308508 BLAKE2B 20b5f8697963754ac868c547224cb01d50e4a6e4bb
 DIST tox-4.61.5.tar.gz.provenance 9673 BLAKE2B 0d029219e08eb4f28eaca0d0ffcc48492d0dbd8cf0b7a9ed87485fcc5271918928f47d3ad7f421984d874f36c3422693b7f292d6b2049066b8b810012eacd04e SHA512 6a79178a46bd71eb5a8b3a383384ccb5fd71ef3f845b5adf32722d7501be5f98f2076e8803597f8fdd88f4ff8848648bb62247b0ce757c0e16e496b2f0289a7c
 DIST tox-4.62.0.tar.gz 309684 BLAKE2B b296169ce5691c141cf6362c0d032734acb54d348fa7f505f2910b1ab0c10f91af1d915282f610ed3b4f81ac0691ee381f41e7fa2f030de03ebaa93e95401a20 SHA512 f68a48eb65051f0352f431db49c405e42bccf3568c18584980d37d0b59a55ef7a7c2f1b6501d87b85845f9b224960eb5a2698356b3f75d8e914fdd1424319d8a
 DIST tox-4.62.0.tar.gz.provenance 9497 BLAKE2B 602dd61ae1ce851fe78bd62905aa155ab992260dced5ff8981882c897713848a5bca66ea005c01b1e719315466d2bb7ba30d07948b656b3d75a32fa8e6dd1e31 SHA512 bf0c3f43f5a3c069cf3a666188afce2faab3726a619c9c55bb0647f36a2471730fb6abc9a39912297e773bfabd08a87bb445c6a458f8da582faf3aad2005c78e
+DIST tox-4.63.0.tar.gz 310965 BLAKE2B 6ddf45f8bcb2f673136004e5da559f07a64ad5120ae2437f2cd498beb39fcdafe543b4242b90088b56de167516efcc9856914a003c9a79d104742c1d2f3f696a SHA512 4f266d3eff95592aa6648e6e868c6d61c149e4975d092ef2470085819f343ada1027c1484723e8720b030fee495ded957c0c60454a100da7efd46d7a0f54368a
+DIST tox-4.63.0.tar.gz.provenance 9532 BLAKE2B b9e09d929dcc516aa81b61cda0ee7940d854b9da8f124a99a21927dc7896a554dd339d185367bac136a4bb86420dc915fa91f90297a3395d0cce39967c17d9fa SHA512 3e321cb8d1eb4213c7445800b6c5d7f87599f72d26c80fbb67bf69ab1acc6dd4f1bafdedd8fa4a6323b49a68872a13b02d5b8598e8690f465d92585cc79316cc
diff --git a/dev-python/tox/tox-4.63.0.ebuild b/dev-python/tox/tox-4.63.0.ebuild
new file mode 100644
index 0000000000000..c88c0a344a44a
--- /dev/null
+++ b/dev-python/tox/tox-4.63.0.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYPI_VERIFY_REPO=https://github.com/tox-dev/tox
+PYTHON_COMPAT=( python3_{12..15} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="virtualenv-based automation of test activities"
+HOMEPAGE="
+	https://tox.readthedocs.io/
+	https://github.com/tox-dev/tox/
+	https://pypi.org/project/tox/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~m68k ~ppc ~ppc64 ~riscv ~s390 ~x86"
+
+RDEPEND="
+	dev-python/cachetools[${PYTHON_USEDEP}]
+	dev-python/colorama[${PYTHON_USEDEP}]
+	dev-python/filelock[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/platformdirs[${PYTHON_USEDEP}]
+	dev-python/pluggy[${PYTHON_USEDEP}]
+	dev-python/pyproject-api[${PYTHON_USEDEP}]
+	dev-python/python-discovery[${PYTHON_USEDEP}]
+	dev-python/tomli-w[${PYTHON_USEDEP}]
+	dev-python/virtualenv[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/typing-extensions-4.15[${PYTHON_USEDEP}]
+	' 3.12)
+"
+BDEPEND="
+	dev-python/docutils[${PYTHON_USEDEP}]
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		dev-python/argcomplete[${PYTHON_USEDEP}]
+		dev-python/build[${PYTHON_USEDEP}]
+		dev-python/distlib[${PYTHON_USEDEP}]
+		dev-python/psutil[${PYTHON_USEDEP}]
+		dev-python/re-assert[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-{mock,rerunfailures,timeout,xdist} time-machine )
+EPYTEST_RERUNS=3
+# upstream timeouts are quite short
+: ${EPYTEST_TIMEOUT:=180}
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	# upstream lower bounds are meaningless
+	sed -i -e 's:>=[0-9.]*::' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# devpi_process is not packaged, and has lots of dependencies
+	cat > "${T}"/devpi_process.py <<-EOF || die
+		def IndexServer(*args, **kwargs): raise NotImplementedError()
+	EOF
+
+	local -x PYTHONPATH=${T}:${PYTHONPATH}
+	local EPYTEST_DESELECT=(
+		# Internet
+		tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_build_wheel_external
+		tests/tox_env/python/virtual_env/package/test_package_cmd_builder.py::test_run_installpkg_targz
+		tests/tox_env/python/virtual_env/package/test_package_pyproject.py::test_pyproject_installpkg_pep517_envs
+		# require tombi
+		tests/session/cmd/test_schema.py::test_schema_tombi_lint
+	)
+	local EPYTEST_IGNORE=(
+		# requires devpi*
+		tests/test_provision.py
+	)
+
+	epytest -o addopts=
+}