dev-java/openjdk-jre-bin: bump to 8.242_p08

Package-Manager: Portage-2.3.84, Repoman-2.3.16
Signed-off-by: Georgy Yakovlev <gyakovlev@gentoo.org>

dev-java/openjdk-jre-bin/Manifest

@@ -2,3 +2,4 @@ DIST OpenJDK11U-jre_x64_linux_hotspot_11.0.4_11.tar.gz 42055392 BLAKE2B d9634ee9
 DIST OpenJDK11U-jre_x64_linux_hotspot_11.0.5_10.tar.gz 42132415 BLAKE2B f857b9618f653ce3df1a1f6b3a3f3fd0ceaaa2d66b9d58872817fdbb7846195459b0fd1d79cddb444e0cd17faafc46bcea85fa22b810d2e93b95a9829da6dad5 SHA512 b13ee8af718c701195765eb6c36c8a6dfc32a5a39f8da4118db4e5ef8ab2012f8952cea73a964fcac079487b6372c0be727f0f2df43b948ccdd4663e6b327d1d
 DIST OpenJDK8U-jre_x64_linux_hotspot_8u222b10.tar.gz 40934975 BLAKE2B e03bfb1896e140b79474a4c9004a97aa07bc9fb29c608b2320c05625a56936555ff8ffda7c9656a2d3ff7628bac769e4d14694b2be6d08e4c90b0e6802a05afb SHA512 e1810c4115206cf78c69b971354474098e853c786b472c2140b9e16187efcd3e15bfff26e743e7a532a6f0619f4728482348583662c1eeccd1ebbb82b980f8af
 DIST OpenJDK8U-jre_x64_linux_hotspot_8u232b09.tar.gz 40963409 BLAKE2B 16f0cce76aad30ed27c84f5bf5e5469c947023d8ab07886013e50ce9af31c90df11dfdce6fa220ff5d59b511dcb7ef4df7dc73fa7a7648d2e92899a81eec6109 SHA512 5ce98215c36d2870ebf0112205dfae39c3d43528ebe175dd16ff54b16267b44ada5d5d26e7d7744db95c3c8faee2858fad59c92b065993397defa64cb58c294e
+DIST OpenJDK8U-jre_x64_linux_hotspot_8u242b08.tar.gz 40987250 BLAKE2B ba3f15b938b4462a186c13ca8ea12c5e5e5bbfe5e716af1911e9525875e6956caf3155423f32433be05ebd1a3c873d94b33a797298d6d09577a775c7dfe2a658 SHA512 11dddf75813aa3b88b2bfb2ca89e186cc15601f75ec4f9cbe92c8b60f61438f75a76e45c26bc614eb54de16a584e906f8935cb2146937b96f2970eb89dddea09

dev-java/openjdk-jre-bin/openjdk-jre-bin-8.242_p08.ebuild

@@ -0,0 +1,84 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eapi7-ver java-vm-2
+
+abi_uri() {
+	echo "${2-$1}? (
+			https://github.com/AdoptOpenJDK/openjdk${SLOT}-binaries/releases/download/jdk${MY_PV}/OpenJDK8U-jre_${1}_linux_hotspot_${MY_PV/-/}.tar.gz
+		)"
+}
+
+MY_PV=$(ver_rs 1 'u' 2 '-' ${PV//p/b})
+SLOT="$(ver_cut 1)"
+
+DESCRIPTION="Prebuilt Java JRE binaries provided by AdoptOpenJDK"
+HOMEPAGE="https://adoptopenjdk.net"
+SRC_URI="
+	$(abi_uri x64 amd64)
+"
+
+LICENSE="GPL-2-with-classpath-exception"
+KEYWORDS="~amd64"
+
+IUSE="alsa cups headless-awt nsplugin selinux webstart"
+
+RDEPEND="
+	media-libs/fontconfig:1.0
+	media-libs/freetype:2
+	>net-libs/libnet-1.1
+	>=sys-apps/baselayout-java-0.1.0-r1
+	>=sys-libs/glibc-2.2.5:*
+	sys-libs/zlib
+	alsa? ( media-libs/alsa-lib )
+	cups? ( net-print/cups )
+	selinux? ( sec-policy/selinux-java )
+	!headless-awt? (
+		x11-libs/libX11
+		x11-libs/libXext
+		x11-libs/libXi
+		x11-libs/libXrender
+		x11-libs/libXtst
+	)"
+
+PDEPEND="
+	webstart? ( >=dev-java/icedtea-web-1.6.1:0 )
+	nsplugin? ( >=dev-java/icedtea-web-1.6.1:0[nsplugin] )"
+
+RESTRICT="preserve-libs splitdebug"
+QA_PREBUILT="*"
+
+S="${WORKDIR}/jdk${MY_PV}-jre"
+
+src_install() {
+	local dest="/opt/${P}"
+	local ddest="${ED%/}/${dest#/}"
+
+	rm ASSEMBLY_EXCEPTION LICENSE THIRD_PARTY_README || die
+
+	# this does not exist on arm64 hence -f
+	rm -fv lib/*/libfreetype.so* || die
+
+	if ! use alsa ; then
+		rm -v lib/*/libjsoundalsa.so* || die
+	fi
+
+	if use headless-awt ; then
+		rm -fvr lib/*/lib*{[jx]awt,splashscreen}* \
+			bin/policytool || die
+	fi
+
+	rm -v lib/security/cacerts || die
+
+	dodir "${dest}"
+	cp -pPR * "${ddest}" || die
+
+	dosym "${EPREFIX}"/etc/ssl/certs/java/cacerts "${dest}"/lib/security/cacerts
+
+	java-vm_install-env "${FILESDIR}"/${PN}-${SLOT}.env.sh
+	java-vm_set-pax-markings "${ddest}"
+	java-vm_revdep-mask
+	java-vm_sandbox-predict /dev/random /proc/self/coredump_filter
+}