dev-python/hcloud-python: initial commit

Signed-off-by: Agostino Sarubbo <ago@gentoo.org>
Package-Manager: Portage-2.3.62, Repoman-2.3.11

dev-python/hcloud-python/hcloud-python-1.2.1.ebuild

@@ -0,0 +1,41 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python{2_7,3_5,3_6,3_7} )
+
+inherit distutils-r1
+
+DESCRIPTION="Official Hetzner Cloud python library"
+HOMEPAGE="https://github.com/hetznercloud/hcloud-python"
+SRC_URI="https://github.com/hetznercloud/${PN}/archive/v1.2.1.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="doc examples"
+
+RDEPEND="dev-python/future[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
+DEPEND="${RDEPEND}"
+
+# it can be delete for the next release bump
+# https://github.com/hetznercloud/hcloud-python/pull/41
+python_prepare_all() {
+	rm -fr tests || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_install_all() {
+	use examples && dodoc -r examples
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+
+	distutils-r1_python_install_all
+}