dev-python/m2r: Version bump

Package-Manager: Portage-2.3.6_p2, Repoman-2.3.2_p70

dev-python/m2r/Manifest

@@ -1 +1,2 @@
 DIST m2r-0.1.5.tar.gz 13202 SHA256 3448f770aed05ca10390d0917cd51836cbf82a2f095bc91507e6291cfab03223 SHA512 78e9e8daa293b2466c95f0adad937fa0bbefaf0dd9663695bb916be13182633e0d462afa5331a595db424420485ef54bbfd4e0625962026fab4ce0c63104bc84 WHIRLPOOL c701aa0a735eda9b7eaab7ff6f384bad7535337f6a7adcfce2d729f33b01aed9213d04fcfe1dc3521b2df0687f2b849a3eb5df628a87ea3ea2697ae389ad8438
+DIST m2r-0.1.6.tar.gz 13615 SHA256 a26bc2e25e0ad3f8650385aea25cf734ac4fcd30e54faec92fd39675da75e527 SHA512 3641cf4013f71fbd43d6cdad530cfd3e909c93709edfbd79d6a51e7121de68e279d3ec4eb7eed391a35902ffa467310bd6b020139b2024c3e80fa44e5f6cc4a7 WHIRLPOOL 4bc6ed787069483f4f4c5bcbb4c9cc448dd2d2edc0a7845e2ca74189a0a8b25040c1fed293e4c4aebf6ea1640f69cb777c4621db79a6008b887b8199247712a9

dev-python/m2r/m2r-0.1.6.ebuild

@@ -0,0 +1,49 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} pypy)
+
+inherit distutils-r1
+
+DESCRIPTION="Markdown to reStructuredText converter"
+HOMEPAGE="https://github.com/miyakogi/m2r https://pypi.python.org/pypi/m2r"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc64 ~x86"
+IUSE="test"
+
+RDEPEND="
+	dev-python/mistune[${PYTHON_USEDEP}]
+	dev-python/docutils[${PYTHON_USEDEP}]
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? ( $(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' python2_7) )
+	${RDEPEND}
+"
+
+#S=${WORKDIR}/${P}
+
+python_prepare_all() {
+	# fix a Q/A violation, trying to install the tests as an independant package
+	sed -e "s/packages=\['tests'\],/packages=[],/" -i setup.py
+	# remove duped old file in the tarball
+	rm "tests/test_r s.py" || die
+	# add missing test files
+	cp "${FILESDIR}/"test.md tests/ || die
+	cp "${FILESDIR}/"test.rst tests/ || die
+	cp "${FILESDIR}/"m2r.1 ./ || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	py.test -v || die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	doman m2r.1
+}