diff --git a/kde-plasma/drkonqi-legacy/Manifest b/kde-plasma/drkonqi-legacy/Manifest
new file mode 100644
index 0000000000000..843f18b7714e0
--- /dev/null
+++ b/kde-plasma/drkonqi-legacy/Manifest
@@ -0,0 +1 @@
+DIST drkonqi-6.3.80_p20250417-8fd0ba78.tar.gz 2147277 BLAKE2B 76107222910c03aaf234129d6f0728db2b21e425ce8dc4387863c845643f52d7e02beb2bf3fb68ab50efda8c4b85a053f3580ad634113a7fa1b07d992dd2d205 SHA512 373cd702349661101e5d6420b641366992184f823533afd54139738fc907f6420394807884a551f4d76eb87b6bd157c9de66eb9d339e4277aca4cc91dca13a7b
diff --git a/kde-plasma/drkonqi-legacy/drkonqi-legacy-6.3.80_p20250417.ebuild b/kde-plasma/drkonqi-legacy/drkonqi-legacy-6.3.80_p20250417.ebuild
new file mode 100644
index 0000000000000..821830d7f979c
--- /dev/null
+++ b/kde-plasma/drkonqi-legacy/drkonqi-legacy-6.3.80_p20250417.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="true"
+KDE_ORG_COMMIT="8fd0ba78c76fbabae22ec81f4d9c4f8204d0df94"
+KDE_ORG_NAME="drkonqi"
+PYTHON_COMPAT=( python3_{11..13} )
+KFMIN=6.14.0
+QTMIN=6.8.1
+inherit ecm plasma.kde.org python-single-r1 xdg
+
+DESCRIPTION="Plasma crash handler, gives the user feedback if a program crashed"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="6"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE=""
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="test" # bug 935362
+
+COMMON_DEPEND="${PYTHON_DEPS}
+	>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,network,widgets]
+	>=dev-qt/qtdeclarative-${QTMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kcrash-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kidletime-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/kjobwidgets-${KFMIN}:6
+	>=kde-frameworks/knotifications-${KFMIN}:6
+	>=kde-frameworks/kservice-${KFMIN}:6
+	>=kde-frameworks/kstatusnotifieritem-${KFMIN}:6
+	>=kde-frameworks/kwallet-${KFMIN}:6
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+	>=kde-frameworks/kwindowsystem-${KFMIN}:6
+	>=kde-frameworks/syntax-highlighting-${KFMIN}:6
+	>=sys-auth/polkit-qt-0.175.0[qt6(+)]
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-qt/qtbase-${QTMIN}:6[concurrent]
+	test? ( >=dev-qt/qtbase-${QTMIN}:6[network] )
+"
+RDEPEND="${COMMON_DEPEND}
+	!kde-plasma/drkonqi
+	dev-libs/elfutils[utils]
+	>=kde-frameworks/kirigami-${KFMIN}:6
+	>=kde-frameworks/kitemmodels-${KFMIN}:6
+	$(python_gen_cond_dep '
+		dev-python/psutil[${PYTHON_USEDEP}]
+		dev-python/pygdbmi[${PYTHON_USEDEP}]
+	')
+	|| (
+		>=dev-debug/gdb-12
+		llvm-core/lldb
+	)
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_PYTHON_VENDORING=OFF
+		-DWITH_SYSTEMD=OFF # non-systemd snapshot before it was made required
+	)
+	ecm_src_configure
+}
+
+src_test() {
+	# needs network access, bug #698510
+	local myctestargs=(
+		-E "(connectiontest)"
+	)
+	ecm_src_test
+}
diff --git a/kde-plasma/drkonqi-legacy/metadata.xml b/kde-plasma/drkonqi-legacy/metadata.xml
new file mode 100644
index 0000000000000..92618c1810d1e
--- /dev/null
+++ b/kde-plasma/drkonqi-legacy/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>kde@gentoo.org</email>
+		<name>Gentoo KDE Project</name>
+	</maintainer>
+	<upstream>
+		<bugs-to>https://bugs.kde.org/enter_bug.cgi?classification=Plasma</bugs-to>
+		<remote-id type="kde-invent">plasma/drkonqi</remote-id>
+	</upstream>
+</pkgmetadata>