dev-python/pbr: Version Bump

Package-Manager: portage-2.2.20.1
Signed-off-by: Justin Lecher <jlec@gentoo.org>

dev-python/pbr/Manifest

@@ -7,3 +7,4 @@ DIST pbr-1.2.0.tar.gz 99092 SHA256 1543fc3e00261369c160fc8cf700717aad15fbc1f0ea0
 DIST pbr-1.3.0.tar.gz 99701 SHA256 1a6f8d514fc11d2571c75c207d932c106f024f199b5f12d25f8ca022b026c59d SHA512 29f661a1d8bed6df5017bb342209e702f19e72c321952a9131d84222162599208bea67922485a87b6f3505e072d62cb13fdfcdd4fbb7c085b3476f6ff5a07df9 WHIRLPOOL 978d943efd2f582b8067a898f102005c749df8addee4ec3d6f4f4c4078e3190263ceba46409281e7bd38ab59ad12f45d3d208cfd6ba58ece72d973161dfd08e9
 DIST pbr-1.6.0.tar.gz 99945 SHA256 4eaee8ff5544703edd1951ed1dc0b283da99a74f740d9f9055eeefcf329de1d1 SHA512 a0393cc7774ea3e181ba75c976f5961686afeb214d8c16f3fdd3838154323cd856ded759cae1c6a25b0371c72d95e579b04de0902d56c432ef137f820032c0fd WHIRLPOOL f0a4c4744a86ee1285490ec78fa8e9dc910d926b05746ccf1be5342fe4369bf33a6373ff4fc9981f2547fa83dbc743de4b204a79c9eee8bd4396a983c5509686
 DIST pbr-1.7.0.tar.gz 99850 SHA256 d6e696dbd2b311225e3a21fe11d611989434cb366ff7919cef5ef1add859526e SHA512 333c99132008997b988f93488b1c4d42a30e14ee179866ee4624bdaae3c11ea2bd321d15c86ee435d325dd80fe1de64ff75113c2c8f5f7b31248188c9e3719fe WHIRLPOOL 62effaec7fb99c89dbba36af71208472c4cfb7fbbb2549440f995048b1ff0b0b2899b099774574c5501bc2d575253a6c8e5df7afccd449f3052a0ebf07f1269e
+DIST pbr-1.8.0.tar.gz 102868 SHA256 44a0ef9295bb59698f461124741a21a0f7f76d42e160d8a0a4bf1693338036fc SHA512 e1c1e7f0ebff7d7dc8af6c3a6fe1841ee80a9620b25f4146bd30ccbd2212e6332fa8c2aa1ca044cda2915a8bad6df468bd1dc365c330508fa8f07b8fa231736f WHIRLPOOL 9fe6546bef29a3f19d3e8f1ca09ce6f004e17bcadfb3fb5460d9a0db382f3e76218637ad8e34f4e5b6ae7caa8c38a54563ec1193b0ea7e5a56da71c48681dd3c

dev-python/pbr/pbr-1.8.0.ebuild

@@ -0,0 +1,64 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Inject some useful and sensible default behaviors into setuptools"
+HOMEPAGE="https://github.com/openstack-dev/pbr"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~mips ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="test"
+
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/coverage-3.6[${PYTHON_USEDEP}]
+		>=dev-python/fixtures-1.3.1[${PYTHON_USEDEP}]
+		>=dev-python/mock-1.2[${PYTHON_USEDEP}]
+		>=dev-python/subunit-0.0.18[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-1.1.2[${PYTHON_USEDEP}]
+		!~dev-python/sphinx-1.2.0[${PYTHON_USEDEP}]
+		<dev-python/sphinx-1.3[${PYTHON_USEDEP}]
+		>=dev-python/six-1.9.0[${PYTHON_USEDEP}]
+		>=dev-python/testrepository-0.0.18[${PYTHON_USEDEP}]
+		>=dev-python/testresources-0.2.4[${PYTHON_USEDEP}]
+		>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+		>=dev-python/testtools-1.4.0[${PYTHON_USEDEP}]
+		dev-python/virtualenv[${PYTHON_USEDEP}]
+	)"
+PDEPEND="dev-python/pip[${PYTHON_USEDEP}]"
+
+# Requ'd for testsuite
+DISTUTILS_IN_SOURCE_BUILD=1
+
+# This normally actually belongs here.
+python_prepare_all() {
+	# This test passes when run within the source and doesn't represent a failure, but rather
+	# a gentoo sandbox constraint
+	# Rm tests that rely upon the package being already installed and fail
+	sed -e s':test_console_script_develop:_&:' \
+		-e s':test_console_script_install:_&:' \
+		-e s':test_sdist_extra_files:_&:' \
+		-e s':test_command_hooks:_&:' \
+		-e s':test_sdist_git_extra_files:_&:' \
+		-i pbr/tests/test_core.py || die
+	sed -e s':test_command_hooks:_&:' \
+		-e s':test_global_setup_hooks:_&:' \
+		-i pbr/tests/test_hooks.py || die
+	einfo "rogue tests disabled"
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	# Note; Tests, that have been removed, pass once package is emerged.
+	esetup.py testr
+}