net-p2p/ktorrent: 25.08.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

net-p2p/ktorrent/Manifest

@@ -1 +1,2 @@
 DIST ktorrent-25.04.3.tar.xz 2229616 BLAKE2B 461658051898cad58933fb54d007346c8038df0a83f3a7ed61816366bbc34cdb322cce1823fd48879796f4bda1d8b30d129e75b1e3cd023713a6eecd51442a51 SHA512 72f5c758bcfac1ebad3bff479cda9d3738326086c36702fa7e22d8e1b1ff43151f8d1b3dd8b62d3c9c83cdf2b83b97aec8bee08c1a0e78523cc4d477c6f9b8e7
+DIST ktorrent-25.08.0.tar.xz 2236464 BLAKE2B c26b22c56292c726f2bebb60ddea65c5b884cf5b479990f11439e6bd3498a50d558bf31e552c835b1d6352a1a67dd0dd45e9ee05b4235a5f4bbe3b437f755876 SHA512 ae3a5e3262eaf9fcecc8d20a320d3d360ea885f1e67ea56fbb78cabf09be54df3d63f27f9a82a9151844f5102b5d5a799e9510d1c7dfa71ca1c8918559b2a96b

net-p2p/ktorrent/ktorrent-25.08.0.ebuild

@@ -0,0 +1,90 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+ECM_TEST="true"
+KFMIN=6.16.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=6.9.1
+inherit ecm gear.kde.org xdg
+
+DESCRIPTION="Powerful BitTorrent client based on KDE Frameworks"
+HOMEPAGE="https://apps.kde.org/ktorrent/"
+
+LICENSE="GPL-2"
+SLOT="6"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="+bwscheduler +downloadorder +infowidget +ipfilter +logviewer +magnetgenerator
++mediaplayer rss +scanfolder +shutdown +stats +upnp +webengine +zeroconf"
+
+COMMON_DEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,network,widgets,xml]
+	>=kde-frameworks/kcmutils-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kcrash-${KFMIN}:6
+	>=kde-frameworks/kdbusaddons-${KFMIN}:6
+	>=kde-frameworks/kglobalaccel-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kiconthemes-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/knotifications-${KFMIN}:6
+	>=kde-frameworks/knotifyconfig-${KFMIN}:6
+	>=kde-frameworks/kparts-${KFMIN}:6
+	>=kde-frameworks/kstatusnotifieritem-${KFMIN}:6
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+	>=kde-frameworks/kwindowsystem-${KFMIN}:6
+	>=kde-frameworks/kxmlgui-${KFMIN}:6
+	>=net-libs/libktorrent-${PVCUT}:6
+	infowidget? ( dev-libs/geoip )
+	ipfilter? ( >=kde-frameworks/karchive-${KFMIN}:6 )
+	mediaplayer? (
+		>=media-libs/phonon-4.12.0[qt6(+)]
+		>=media-libs/taglib-1.5:=
+	)
+	rss? (
+		>=dev-qt/qtwebengine-${QTMIN}:6
+		>=kde-frameworks/syndication-${KFMIN}:6
+	)
+	stats? ( >=kde-frameworks/kplotting-${KFMIN}:6 )
+	upnp? ( >=kde-frameworks/kcompletion-${KFMIN}:6 )
+	webengine? ( >=dev-qt/qtwebengine-${QTMIN}:6 )
+	zeroconf? ( >=kde-frameworks/kdnssd-${KFMIN}:6 )
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-libs/boost-1.71
+"
+RDEPEND="${COMMON_DEPEND}
+	ipfilter? (
+		app-arch/bzip2
+		app-arch/unzip
+		kde-apps/kio-extras:6
+		>=kde-frameworks/ktextwidgets-${KFMIN}:6
+	)
+"
+BDEPEND="sys-devel/gettext"
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_BWSCHEDULER_PLUGIN=$(usex bwscheduler)
+		-DENABLE_DOWNLOADORDER_PLUGIN=$(usex downloadorder)
+		-DENABLE_INFOWIDGET_PLUGIN=$(usex infowidget)
+		-DENABLE_IPFILTER_PLUGIN=$(usex ipfilter)
+		-DENABLE_LOGVIEWER_PLUGIN=$(usex logviewer)
+		-DENABLE_MAGNETGENERATOR_PLUGIN=$(usex magnetgenerator)
+		-DENABLE_MEDIAPLAYER_PLUGIN=$(usex mediaplayer)
+		$(cmake_use_find_package rss KF6Syndication)
+		-DENABLE_SCANFOLDER_PLUGIN=$(usex scanfolder)
+		-DENABLE_SHUTDOWN_PLUGIN=$(usex shutdown)
+		-DENABLE_STATS_PLUGIN=$(usex stats)
+		-DENABLE_UPNP_PLUGIN=$(usex upnp)
+		-DENABLE_SEARCH_PLUGIN=$(usex webengine)
+		-DENABLE_ZEROCONF_PLUGIN=$(usex zeroconf)
+	)
+# add back when ported
+# 		-DENABLE_WEBINTERFACE_PLUGIN=$(usex webinterface)
+	ecm_src_configure
+}