dev-python/astropy: Version bump

Package-Manager: portage-2.2.27

dev-python/pyfits/Manifest

@@ -1 +1,2 @@
 DIST pyfits-3.3.tar.gz 1646403 SHA256 becb6dcc7e443138b9d239db7a0e8ad939e6e047c2c9ca86e84d0672da425fa1 SHA512 561fe61050e61745054e0e4712c4413e129293b062d2020219b61d648d7093ce6952e1f26da955a1bf570f76ba7eddeb1805c99f679300b072ef6bacc2e4c90a WHIRLPOOL 9b4b5dd236713359a9441e4179486e4b56ec11b7fc25c3abb59d30a6267fe87496601778731ba7ff92c55243621aa58ca493821b83224fde41a79f18c21e485b
+DIST pyfits-3.4.tar.gz 1692414 SHA256 ce0319cf6ef40846c5915202e4c8bd8d293ad85af4b14aa5a60fb285b7538c4b SHA512 b569f871f26dcd9cb2fbe9d823d55c525e8101b0fcf83fff4bc3f3ec4bc7f680953a29634518ea19383f533f5e23b3703fffdb4e0d577b1023b4323254ef3a7e WHIRLPOOL a121ca9b4d7b4457d24e905e8506402043679800eddc5c5813b68612bae1ee80940eb723f03504c9136fc5c2bac1a419aa52f87394689ae1099bb5002e77417e

dev-python/pyfits/pyfits-3.4.ebuild

@@ -0,0 +1,71 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 python3_{4,5} )
+
+inherit distutils-r1 eutils multilib
+
+DESCRIPTION="Provides an interface to FITS formatted files under python"
+HOMEPAGE="http://www.stsci.edu/resources/software_hardware/pyfits"
+SRC_URI="mirror://pypi/p/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="doc test"
+
+RDEPEND="
+	dev-python/numpy[${PYTHON_USEDEP}]
+	sci-libs/cfitsio:0="
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/d2to1-0.2.5[${PYTHON_USEDEP}]
+	>=dev-python/stsci-distutils-0.3[${PYTHON_USEDEP}]
+	doc? (
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep 'dev-python/numpydoc[${PYTHON_USEDEP}]' 'python*')
+		dev-python/sphinxcontrib-programoutput[${PYTHON_USEDEP}]
+		dev-python/stsci-sphinxext[${PYTHON_USEDEP}]
+		 )
+	test? ( dev-python/nose[${PYTHON_USEDEP}] )"
+
+PATCHES=( "${FILESDIR}"/${PN}-3.2.1-unbundle-cfitsio.patch )
+
+python_prepare_all() {
+	sed -i \
+		-e "s/\(hook_package_dir = \)lib/\1$(get_libdir)/g" \
+		"${S}"/setup.cfg || die
+
+	# https://github.com/spacetelescope/PyFITS/issues/95
+	sed -e "s/except UserWarning, w/except UserWarning as w/" \
+		-i pyfits/scripts/fitscheck.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	cd "${BUILD_DIR}"/lib* || die
+	nosetests --verbose || die
+}
+
+python_install() {
+	distutils-r1_python_install
+	local binary
+	for binary in "${ED}"/usr/bin/* "${D}$(python_get_scriptdir)"/*; do
+		einfo "Renaming ${binary} to ${binary}-${PN}"
+		mv ${binary}{,-${PN}} || die "failed renaming"
+	done
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/build/html/. )
+	DOCS=( FAQ.txt CHANGES.txt )
+	distutils-r1_python_install_all
+}