dev-python/gevent: version bump

Signed-off-by: Alexys Jacob <ultrabug@gentoo.org>
Package-Manager: Portage-2.3.50, Repoman-2.3.11

dev-python/gevent/Manifest

@@ -2,3 +2,4 @@ DIST gevent-1.0.1.tar.gz 1455636 BLAKE2B 1de7c6986db96f8568a43aef1ff3c9b80b09047
 DIST gevent-1.2.1.tar.gz 2808619 BLAKE2B 2e3c15adb33401012951f0f93fe7f17c1c7597bb4021a4a9ebc7ecae390565d9892bb2fffe9cdac4f7e207d97d50da5d335ed8e42070d67d6be617cf955eb0b4 SHA512 22740e8e114869c1f53bcfd6796226927a3a726d4fd49d104b947f0c97546c7490eabea98b4492db794e21d26d0aee85f1e40b01d386a47063b042a719e61726
 DIST gevent-1.2.2.tar.gz 3108671 BLAKE2B f80df00f58ae2f65aa7f65fc9eac5cbf63a0084f24ccebc71ba9bafba72cd48fff2e7d0b1d8de7939dc669d7708e120fc14077cc845fe3ce212d6a80a42b5158 SHA512 1e2dd544cffea62ee32de2e4066b3f4c121058a1211b89da281ec3882f3763217fe2d346ce38b66e27df9f59cfe05bb137d1608a681dd10eaf06a33dc22f531c
 DIST gevent-1.3.5.tar.gz 4609085 BLAKE2B 55cb4111c9eaf9bbf636c9f1ef8d695def15a92e5591a0c441aae27f41a126487b37b8cc7a701a43453109f24114e3a0c584dff4b9b202018fd8334f0bae8e8d SHA512 4fd6d66e62437c859d653de4e981500fb3a025e6608b91fbb3d5ba4d8f0bff7cce980c03484c1c160a608427979ca763a6660d40ffcb45df4abe5f152ce65d1c
+DIST gevent-1.3.7.tar.gz 4614437 BLAKE2B 43d50c36fba2bedf41a7b33d38180f096b18846146953fa68325155f4a3cb6edb7352b9bb4cff5c7eca7a06ac25dc5b3e82a04545704fd0d6f43e9839a8749a1 SHA512 6dba487a9527eb352dc6a5f57120bf7973da655b3a331cad6637271b626c6e9e5439b20ee8abd9035ecb36e5259c99c69dea5ecdb8fa7ad0dbe28876c4d746d8

dev-python/gevent/gevent-1.3.7.ebuild

@@ -0,0 +1,72 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6,7} pypy )
+PYTHON_REQ_USE="ssl(+),threads(+)"
+
+inherit distutils-r1 flag-o-matic
+
+MY_PV=${PV/_beta/b}
+MY_P=${PN}-${MY_PV}
+
+DESCRIPTION="Coroutine-based network library"
+HOMEPAGE="http://gevent.org/ https://pypi.org/project/gevent/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${MY_P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~mips ~ppc ~ppc64 ~s390 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc examples"
+
+RDEPEND="
+	>=dev-libs/libev-4.23
+	>=net-dns/c-ares-1.12
+	>=dev-python/greenlet-0.4.14
+	virtual/python-greenlet[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
+
+# Tests take long and fail terribly a few times.
+# It also seems that they require network access.
+RESTRICT="test"
+
+S=${WORKDIR}/${MY_P}
+
+python_prepare_all() {
+	export LIBEV_EMBED="false"
+	export CARES_EMBED="false"
+	export EMBED="false"
+
+	distutils-r1_python_prepare_all
+}
+
+python_configure_all() {
+	append-flags -fno-strict-aliasing
+}
+
+python_compile_all() {
+	use doc && emake -C doc html
+}
+
+python_test() {
+	cd src/greentest || die
+
+	GEVENT_RESOLVER=thread \
+		"${PYTHON}" testrunner.py --config known_failures.py || die
+	GEVENT_RESOLVER=ares GEVENTARES_SERVERS=8.8.8.8 \
+		"${PYTHON}" testrunner.py --config known_failures.py \
+		--ignore tests_that_dont_use_resolver.txt || die
+	GEVENT_FILE=thread \
+		"${PYTHON}" testrunner.py --config known_failures.py $(grep -l subprocess test_*.py) || die
+}
+
+python_install_all() {
+	local DOCS=( AUTHORS README.rst )
+	use doc && local HTML_DOCS=( doc/_build/html/. )
+	use examples && dodoc -r examples
+
+	distutils-r1_python_install_all
+}