dev-python/sphinxcontrib-programoutput: version bump

Package-Manager: Portage-2.3.6, Repoman-2.3.3

dev-python/sphinxcontrib-programoutput/sphinxcontrib-programoutput-0.11.ebuild

@@ -0,0 +1,44 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} pypy )
+
+inherit distutils-r1
+
+DESCRIPTION="Extension to sphinx to include program output"
+HOMEPAGE="http://sphinxcontrib-programoutput.readthedocs.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+
+IUSE="doc test"
+
+RDEPEND="dev-python/sphinx[${PYTHON_USEDEP}]
+	dev-python/namespace-sphinxcontrib[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)"
+
+python_compile_all() {
+	if use doc; then
+		python_setup
+		esetup.py build_sphinx
+		HTML_DOCS=( "${BUILD_DIR}/sphinx/html/." )
+	fi
+}
+
+python_test() {
+	esetup.py pytest || die
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	find "${ED}" -name '*.pth' -delete || die
+}