From 4ee0743f279a89f109a06eaed789b53ae0cdfd2f Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Tue, 25 Jul 2023 06:34:04 +0200
Subject: [PATCH] dev-python/podman: Bump to 4.6.0
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/podman/Manifest            |  1 +
 dev-python/podman/podman-4.6.0.ebuild | 52 +++++++++++++++++++++++++++
 2 files changed, 53 insertions(+)
 create mode 100644 dev-python/podman/podman-4.6.0.ebuild

diff --git a/dev-python/podman/Manifest b/dev-python/podman/Manifest
index 4c216727c79f5..3cbfd378b1a6b 100644
--- a/dev-python/podman/Manifest
+++ b/dev-python/podman/Manifest
@@ -1 +1,2 @@
 DIST podman-py-4.5.0.gh.tar.gz 179025 BLAKE2B 6725bd79a5fb0a17a75080b323cf62b56a3ef83d20c7113364785e0994a053455a08d9ffb2bbbbfb646fb730367de9bfd838c7eb92053a93a55008c59ec59732 SHA512 903466e11afebd26da65cc363ab49a56255731ea8bc07d202dd80907e1dd6704b5a8542c5a417f3c46ec93882bb21ef6990ae80fe558dfd3310b9272590cbd39
+DIST podman-py-4.6.0.gh.tar.gz 180393 BLAKE2B bb5e32cc57d3e545e28f98857ecdc643aed7eb208b12e14d0bbf961ec4ac115ee709af88e8f541fd2b73aab1c319d10f7835319dacadb52813e05820348c8406 SHA512 4d60d3643e679d68f560988c2b31272703059dc000e6361b44d896df480a72f36df595f0122ee39f44874b76a7286bbf05ea8c045e5afa58bd0c7b0a5a42f2de
diff --git a/dev-python/podman/podman-4.6.0.ebuild b/dev-python/podman/podman-4.6.0.ebuild
new file mode 100644
index 0000000000000..28f1070a6554f
--- /dev/null
+++ b/dev-python/podman/podman-4.6.0.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1
+
+MY_P=podman-py-${PV}
+DESCRIPTION="A library to interact with a Podman server"
+HOMEPAGE="
+	https://github.com/containers/podman-py/
+	https://pypi.org/project/podman/
+"
+SRC_URI="
+	https://github.com/containers/podman-py/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/pyxdg-0.26[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.24[${PYTHON_USEDEP}]
+	dev-python/urllib3[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-1.2.3[${PYTHON_USEDEP}]
+	' 3.10)
+"
+BDEPEND="
+	test? (
+		>=dev-python/requests-mock-1.11.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO
+		podman/tests/unit/test_volumesmanager.py::VolumesManagerTestCase::test_get_404
+	)
+
+	# integration tests require a workable podman server,
+	# and it doesn't seem to work in ebuild env
+	epytest podman/tests/unit
+}