diff --git a/dev-python/hcloud/Manifest b/dev-python/hcloud/Manifest
index 751bc913bac86..3a0fa1c4f4be4 100644
--- a/dev-python/hcloud/Manifest
+++ b/dev-python/hcloud/Manifest
@@ -1 +1,2 @@
 DIST hcloud-python-2.23.0.gh.tar.gz 151968 BLAKE2B f5f0468a5c68192e1813bb5f08b0bda523987b67e39b794989e57f1e0f0506075398990443fffd4df87c5b98d2fc22a020e1b1583d27f26d23c949a331ab8462 SHA512 eebfd11411f2edda739997aa3194f23621c065e75444605f71dcbfcc3dd7dd6ee0e1a351738f5a75d2bc87d57bd288af30b4efa6cccb9cf00751e96424b5314c
+DIST hcloud-python-2.24.0.gh.tar.gz 152444 BLAKE2B 22463dae842f98e6b594c8bd04e3aa5ff1b1a48cfc8c161acf937da31b4fb6119f82ce72aa02224c757045d6b363e1316359356676066e93301803e36e5a7112 SHA512 1c9cbb03619f8f34eb0de354893d443707c855375571ea263df1ac19c4f55cae3fee474d6f28eb16260318d150b16d6977c4191d5c87d48a239eb33cf1fad276
diff --git a/dev-python/hcloud/hcloud-2.24.0.ebuild b/dev-python/hcloud/hcloud-2.24.0.ebuild
new file mode 100644
index 0000000000000..4601900d10157
--- /dev/null
+++ b/dev-python/hcloud/hcloud-2.24.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{12..15} )
+
+inherit distutils-r1
+
+MY_P=hcloud-python-${PV}
+DESCRIPTION="Official Hetzner Cloud python library"
+HOMEPAGE="
+	https://github.com/hetznercloud/hcloud-python/
+	https://pypi.org/project/hcloud/
+"
+# sdist is missing doc assets as of 1.19.0
+# https://github.com/hetznercloud/hcloud-python/pull/183
+SRC_URI="
+	https://github.com/hetznercloud/hcloud-python/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="examples"
+
+RDEPEND="
+	>=dev-python/python-dateutil-2.7.5[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.20[${PYTHON_USEDEP}]
+"
+
+distutils_enable_sphinx docs \
+	dev-python/myst-parser \
+	dev-python/sphinx-rtd-theme
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+EPYTEST_IGNORE=(
+	# Integration tests need docker:
+	# https://github.com/hetznercloud/hcloud-python/blob/master/.travis.yml#L16
+	tests/integration
+)
+
+python_install_all() {
+	use examples && dodoc -r examples
+	distutils-r1_python_install_all
+}