app-emacs/elpy: drop old 1.35.0_p20220627-r1

Signed-off-by: Maciej Barć <xgqt@gentoo.org>

app-emacs/elpy/Manifest

@@ -1,2 +1 @@
-DIST elpy-1.35.0_p20220627.tar.gz 177246 BLAKE2B ded88f89949683000c9be606f3b5d2fc65a943c97e0369505713ecbd4f595a43a7ce560b699ebbdfd4a756703c5fa8fb21af5b4e8a1aa6dbb8a55fe4b7dcc468 SHA512 b9a4588eb83edef69661568b936e278621abad316ae160a00737c546b5eb26abd8ac089b369be212abbe16b66b590d9df73986995d36201c1010da7dc9706f79
 DIST elpy-1.35.0_p20240719.tar.gz 177599 BLAKE2B 5e01191f591417336c2c7cf6bf087470291fffb92e8dcbf8471ad7a41267f79daeb14809942fed6da73a8c33d7faf1ff478b23bc93a50eeec5ebb847a101493b SHA512 c50d2e3a7388cde535deff032a92ca329cd3e70664a75a40e1f50c82059cec6dbe405b3609fd649bcffed1de8f27d7d8ee6c2f28df78114fc701e7ef23d996ba

app-emacs/elpy/elpy-1.35.0_p20220627-r1.ebuild

@@ -1,101 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_SINGLE_IMPL=ON
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{10..12} )
-
-inherit distutils-r1 elisp
-
-DESCRIPTION="Emacs Python Development Environment"
-HOMEPAGE="https://github.com/jorgenschaefer/elpy/"
-
-if [[ "${PV}" == *9999* ]] ; then
-	inherit git-r3
-
-	EGIT_REPO_URI="https://github.com/jorgenschaefer/${PN}.git"
-else
-	[[ "${PV}" == *_p20220627 ]] && COMMIT=de31d30003c515c25ff7bfd3a361c70c298f78bb
-
-	SRC_URI="https://github.com/jorgenschaefer/${PN}/archive/${COMMIT}.tar.gz
-		-> ${P}.tar.gz"
-	S="${WORKDIR}/${PN}-${COMMIT}"
-
-	KEYWORDS="~amd64 ~x86"
-fi
-
-LICENSE="GPL-3+"
-SLOT="0"
-IUSE="test"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	app-emacs/company-mode
-	app-emacs/highlight-indentation
-	app-emacs/pyvenv
-	app-emacs/s
-	app-emacs/yasnippet
-	$(python_gen_cond_dep '
-		dev-python/flake8[${PYTHON_USEDEP}]
-	')
-"
-BDEPEND="
-	${RDEPEND}
-	test? (
-		$(python_gen_cond_dep '
-			dev-python/autopep8[${PYTHON_USEDEP}]
-			dev-python/jedi[${PYTHON_USEDEP}]
-			dev-python/yapf[${PYTHON_USEDEP}]
-		')
-	)
-"
-
-ELISP_REMOVE="
-	elpy/tests/test_black.py
-	elpy/tests/test_yapf.py
-"
-PATCHES=(
-	"${FILESDIR}/${PN}-elpy.el-yas-snippet-dirs.patch"
-	"${FILESDIR}/${PN}-elpy-rpc.el-elpy-rpc-pythonpath.patch"
-)
-
-DOCS=( CONTRIBUTING.rst README.rst )
-SITEFILE="50${PN}-gentoo.el"
-
-distutils_enable_sphinx docs --no-autodoc
-distutils_enable_tests unittest
-
-pkg_setup() {
-	elisp_pkg_setup
-	python-single-r1_pkg_setup
-}
-
-src_prepare() {
-	distutils-r1_src_prepare
-
-	sed -i "${PN}.el" -e "s|@SITEETC@|${EPREFIX}${SITEETC}/${PN}|" || die
-	sed -i "${PN}-rpc.el" -e "s|@PYTHONLIB@|${EPREFIX}/usr/lib/${EPYTHON}|" || die
-
-	rm ${ELISP_REMOVE} || die
-	sed -i elpy/tests/support.py \
-		-e "s|test_should_get_oneline_docstring_for_modules|disabled_&|" || die
-}
-
-src_compile() {
-	distutils-r1_src_compile
-	elisp_src_compile
-}
-
-src_test() {
-	distutils-r1_src_test
-}
-
-src_install() {
-	distutils-r1_src_install
-
-	elisp_src_install
-	insinto "${SITEETC}/${PN}"
-	doins -r snippets
-}