From 4cbf37ad66c5fa2774d70b208d129cbf173dcd82 Mon Sep 17 00:00:00 2001
From: Matt Turner <mattst88@gentoo.org>
Date: Wed, 16 Apr 2025 22:52:30 -0400
Subject: [PATCH] dev-util/mesa_clc: Version bump to 25.0.4

Signed-off-by: Matt Turner <mattst88@gentoo.org>
---
 dev-util/mesa_clc/Manifest               |  1 +
 dev-util/mesa_clc/mesa_clc-25.0.4.ebuild | 95 ++++++++++++++++++++++++
 2 files changed, 96 insertions(+)
 create mode 100644 dev-util/mesa_clc/mesa_clc-25.0.4.ebuild

diff --git a/dev-util/mesa_clc/Manifest b/dev-util/mesa_clc/Manifest
index 1eebbce52eae0..7bf50f45368ee 100644
--- a/dev-util/mesa_clc/Manifest
+++ b/dev-util/mesa_clc/Manifest
@@ -2,3 +2,4 @@ DIST mesa-25.0.0.tar.xz 46643728 BLAKE2B 9aca2416ea4e304d46fda648cb9b8e04caa0534
 DIST mesa-25.0.1.tar.xz 46679784 BLAKE2B 9a73a3321c9f1d7d4384779f647c43bcb536b316dcc9a61b8a78a6f4bfd4642366e418155db5c2190b530cebee434554c6c4d2d59f68a87bb4056467fe601825 SHA512 1ecb1b90c5f78de4c61f177888543778285731faccc6f78d266d4b437f7b422a78b705a6e9fc6c9eab62c08f2573db5dd725eaa9cc9e5bedcaa7d8cfe6b47a1f
 DIST mesa-25.0.2.tar.xz 46705776 BLAKE2B 6e387806e880d518a68b3a8d4cb25071e9d50732aee06cc8b88f717c569c2764d658d40a8710ff362820a30133d5fde6b82ea7fb552fd0f690bcdf276a6f5e67 SHA512 2de8e8b514619d9ad5f407f5e1ff04fff8039d66b5f32257c2e8ca3d9f3b190269066aeba0779d6e0b2a2c0739237382fc6a98ea8563ed97801a809c96163386
 DIST mesa-25.0.3.tar.xz 46736740 BLAKE2B 8b32119756c422b780b466ed4ba60660d2c91f8f460b617f7417e5f3ae2a5cd44a95abedbcdfb8e2f38d99fb2e4f1610586e846fe13b9db979f5156dcc268614 SHA512 a8ddfa3ac31869e82a49d14aaab0659d0496ae77db3f32aa0d5d28de8e1e4cace9fa652451a050fbc79281e8461cd70e86ad464aa387533387187fbcb604aaab
+DIST mesa-25.0.4.tar.xz 46770664 BLAKE2B b661bc1534bff848c32c559ecc790fd7770682aa7f35403c2fb50b899ad83dbbafb2baecf0e372972849378a4a539eeafe5e9c9e1497ab4313ebcafa89f6e248 SHA512 562a97bd0374ff2a76f71c848df4fe542f1fc66c420a9101eb4bb1947d00eee4417d9c6f2d1be19638663753785c19384f8a6dc078c3187448ab79413d906152
diff --git a/dev-util/mesa_clc/mesa_clc-25.0.4.ebuild b/dev-util/mesa_clc/mesa_clc-25.0.4.ebuild
new file mode 100644
index 0000000000000..2d0b93cf95fb9
--- /dev/null
+++ b/dev-util/mesa_clc/mesa_clc-25.0.4.ebuild
@@ -0,0 +1,95 @@
+# Copyright 2023-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LLVM_COMPAT=( {18..19} )
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit llvm-r1 meson python-any-r1
+
+MY_PV="${PV/_/-}"
+
+DESCRIPTION="mesa_clc tool used for building OpenCL C to SPIR-V"
+HOMEPAGE="https://mesa3d.org/"
+
+if [[ ${PV} == 9999 ]]; then
+	S="${WORKDIR}/mesa_clc-${MY_PV}"
+	EGIT_REPO_URI="https://gitlab.freedesktop.org/mesa/mesa.git"
+	inherit git-r3
+else
+	S="${WORKDIR}/mesa-${MY_PV}"
+	SRC_URI="https://archive.mesa3d.org/mesa-${MY_PV}.tar.xz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="debug"
+
+RDEPEND="
+	dev-util/spirv-tools
+	$(llvm_gen_dep '
+		dev-util/spirv-llvm-translator:${LLVM_SLOT}
+		llvm-core/clang:${LLVM_SLOT}=
+		=llvm-core/libclc-${LLVM_SLOT}*
+		llvm-core/llvm:${LLVM_SLOT}=
+	')
+"
+DEPEND="${RDEPEND}
+	dev-libs/expat
+	>=sys-libs/zlib-1.2.8:=
+	x11-libs/libdrm
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	$(python_gen_any_dep "
+		>=dev-python/mako-0.8.0[\${PYTHON_USEDEP}]
+		dev-python/packaging[\${PYTHON_USEDEP}]
+		dev-python/pyyaml[\${PYTHON_USEDEP}]
+	")
+	virtual/pkgconfig
+"
+
+python_check_deps() {
+	python_has_version -b ">=dev-python/mako-0.8.0[${PYTHON_USEDEP}]" &&
+	python_has_version -b "dev-python/packaging[${PYTHON_USEDEP}]" &&
+	python_has_version -b "dev-python/pyyaml[${PYTHON_USEDEP}]" || return 1
+}
+
+pkg_setup() {
+	llvm-r1_pkg_setup
+	python-any-r1_pkg_setup
+}
+
+src_configure() {
+	PKG_CONFIG_PATH="$(get_llvm_prefix)/$(get_libdir)/pkgconfig"
+
+	use debug && EMESON_BUILDTYPE=debug
+
+	local emesonargs=(
+		-Dllvm=enabled
+		-Dshared-llvm=enabled
+		-Dmesa-clc=enabled
+		-Dinstall-mesa-clc=true
+
+		-Dgallium-drivers=''
+		-Dvulkan-drivers=''
+
+		# Set platforms empty to avoid the default "auto" setting. If
+		# platforms is empty meson.build will add surfaceless.
+		-Dplatforms=''
+
+		-Dglx=disabled
+		-Dlibunwind=disabled
+		-Dzstd=disabled
+
+		-Db_ndebug=$(usex debug false true)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	dobin "${BUILD_DIR}"/src/compiler/clc/mesa_clc
+	dobin "${BUILD_DIR}"/src/compiler/spirv/vtn_bindgen
+}