diff --git a/dev-python/gitdb2/Manifest b/dev-python/gitdb2/Manifest
new file mode 100644
index 0000000000000..b0bdc4be55224
--- /dev/null
+++ b/dev-python/gitdb2/Manifest
@@ -0,0 +1 @@
+DIST gitdb2-2.0.2.tar.gz 393188 SHA256 f2e36d7561e91f30a6a44858756dc020d8f1e81ca6e4185979d5c6c24c648070 SHA512 685af97dcb1f352255024b8a382255dacea00aa6312f71d2a16eab00d0204ebf6d46c90d804a4778ea0ef35eae7e5a2f5ae71c16851206fdaf27be8af59499d9 WHIRLPOOL d79705c7bca170f98f47ec7b437af6b9d2b0d1c5fffa57b863ade7a3d4b8e950860f9b1a08aceb5a8c5a2135266a671b7a35bd56f39777a40e8b1afaaadcfdc8
diff --git a/dev-python/gitdb2/gitdb2-2.0.2.ebuild b/dev-python/gitdb2/gitdb2-2.0.2.ebuild
new file mode 100644
index 0000000000000..4aa4893fc0372
--- /dev/null
+++ b/dev-python/gitdb2/gitdb2-2.0.2.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+
+inherit distutils-r1
+
+DESCRIPTION="GitDB is a pure-Python git object database"
+HOMEPAGE="
+	https://github.com/gitpython-developers/gitdb
+	https://pypi.python.org/pypi/gitdb2"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+RDEPEND="
+	!dev-python/gitdb[${PYTHON_USEDEP}]
+	>=dev-python/smmap2-2.0.1[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	test? (
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-vcs/git
+	)"
+
+src_test() {
+	local i
+
+	mkdir "${T}"/repo || die
+	cd "${T}"/repo || die
+
+	for (( i = 0; i < 2500; ++i )); do
+		echo "${i}" > file"${i}" || die
+	done
+
+	git init || die
+	git config user.email "you@example.com" || die
+	git config user.name "Your Name" || die
+	git add -A || die
+	git commit -q -m ".." || die
+	git clone --bare "${T}"/repo "${T}"/repo.git || die
+	cd "${S}" || die
+
+	distutils-r1_src_test
+}
+
+python_test() {
+	#TRAVIS=1 disables performance tests which rely on the gitdb repo
+	local -x TRAVIS=1
+	local -x GITDB_TEST_GIT_REPO_BASE="${T}"/repo.git
+	nosetests -v || die "Tests fail with ${EPYTHON}"
+}
diff --git a/dev-python/gitdb2/metadata.xml b/dev-python/gitdb2/metadata.xml
new file mode 100644
index 0000000000000..005b63ca80565
--- /dev/null
+++ b/dev-python/gitdb2/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <upstream>
+    <remote-id type="pypi">gitdb2</remote-id>
+    <remote-id type="github">gitpython-developers/gitdb</remote-id>
+  </upstream>
+</pkgmetadata>