dev-python/hypothesis: Bump to 5.41.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2020-10-30 18:23:20 +01:00
parent 8ffbea89c1
commit 4be54eb442
2 changed files with 64 additions and 0 deletions
+1
View File
@@ -6,3 +6,4 @@ DIST hypothesis-python-5.37.5.tar.gz 9092380 BLAKE2B b5bf9f5c5bb1002154ea6041c38
DIST hypothesis-python-5.38.0.tar.gz 9092764 BLAKE2B ec805c3df17af88e122e9a462c73768b67d420172d72c088add8056b8de64606a8e6c01f82a0ca4fd05520444482e10b488b4ccf2b78b951288c4e1827e1ce12 SHA512 2a4e57ace3c6487598353bd40a9295d8dd05c6b18493d61674bbb403a4bbd863c43af683b59da990cc5add5dedc789462337140c4d2ed7d2c16567fb254261ff
DIST hypothesis-python-5.38.1.tar.gz 9093201 BLAKE2B 093b847524ca1a4a7ec4172585d8cbdc63820165f367a7f5782c0e94ed190f9f271fe0d76f570a5ab95d794951260b93cb4114ac090b56bcdf904e988c00c4c5 SHA512 26db08680464710246bfa3a3dfddbe41e9480e4ce2a50bf75597aa96efe8976d3b7bcf639e2efe9a8bfec64bdfef3fec14093e14cbe8db3f1cf5dafe813a91a0
DIST hypothesis-python-5.39.0.tar.gz 9094029 BLAKE2B 32f98b9a57993fe95d894625ac2ab44eb52ed1fb301566ad01064a2beb37ae768484797220386c55e5c72f4022819c5be9abaf68b57bfd3385860d8bed9baaaa SHA512 fd683781ea7bf0806cf6f15d0065808e5a83410b9860c23803f9f18ea7be1e372a75221116e1f661f189870141de4b8585029cfcdca5d6140a5140226578a610
DIST hypothesis-python-5.41.0.tar.gz 9094817 BLAKE2B 3025caf9a0ccba19abfd12273edefe1db825a40615a378fb076e8d3ba96bfecc64ec23be6ef72b6fcd89d7d6b5c94bbf12abf3212e4a521a21def892b0d95a56 SHA512 76a0147d36179368d62a3d9e6f9f27effa903476fa0cccdba4574937c470bbfd020daccf9b3df73f457b543b6a94ce0858fe4d9abdfe9c16a8c49858c8bc0e92
@@ -0,0 +1,63 @@
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
DISTUTILS_USE_SETUPTOOLS=rdepend
PYTHON_COMPAT=( python3_{6,7,8,9} pypy3 )
PYTHON_REQ_USE="threads(+),sqlite"
inherit distutils-r1 eutils multiprocessing optfeature
DESCRIPTION="A library for property based testing"
HOMEPAGE="https://github.com/HypothesisWorks/hypothesis https://pypi.org/project/hypothesis/"
SRC_URI="https://github.com/HypothesisWorks/${PN}/archive/${PN}-python-${PV}.tar.gz"
S="${WORKDIR}/${PN}-${PN}-python-${PV}/${PN}-python"
LICENSE="MPL-2.0"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
IUSE="cli test"
RESTRICT="!test? ( test )"
RDEPEND="
>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
>=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
cli? (
$(python_gen_cond_dep '
dev-python/black[${PYTHON_USEDEP}]
dev-python/click[${PYTHON_USEDEP}]
' python3_{6..9})
)
"
BDEPEND="
test? (
${RDEPEND}
dev-python/mock[${PYTHON_USEDEP}]
dev-python/pexpect[${PYTHON_USEDEP}]
>=dev-python/pytest-5.3.5[${PYTHON_USEDEP}]
dev-python/pytest-xdist[${PYTHON_USEDEP}]
!!<dev-python/typing-3.7.4.1
)
"
python_prepare() {
if ! use cli || [[ ${EPYTHON} != python* ]]; then
sed -i -e '/console_scripts/d' setup.py || die
fi
}
python_test() {
pytest -vv tests/cover tests/pytest tests/quality \
-n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")" ||
die "Tests fail with ${EPYTHON}"
}
pkg_postinst() {
optfeature "datetime support" dev-python/pytz
optfeature "dateutil support" dev-python/python-dateutil
optfeature "numpy support" dev-python/numpy
optfeature "django support" dev-python/django dev-python/pytz
optfeature "pandas support" dev-python/pandas
optfeature "pytest support" dev-python/pytest
}