dev-python/zope-testrunner: New package, test dep of zope.exceptions

dev-python/zope-testrunner/Manifest

@@ -0,0 +1 @@
+DIST zope.testrunner-4.6.0.zip 278215 SHA256 f57aa4729c353a137090081ad110d6bdf3a6489108e6878136e907fc14d6edff SHA512 4f90f7111f36cfca95b062cacc947a6f547871e5fb182e56190009217c517566199e79c768fa4a451c945c8916ed596f54b4ff06552bde3a160a7a7e03b22ff5 WHIRLPOOL 26c00298bbbc106d3e0f82a3d6bee382b987f634ef45a532548ef795ec942a2de59526572ad7f66b04dd67ad2044cc6ee9682e350e0870a4954edeed07ce69dc

dev-python/zope-testrunner/metadata.xml

@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+		<name>Python</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="pypi">zope.testrunner</remote-id>
+		<remote-id type="github">zopefoundation/zope.testrunner</remote-id>
+	</upstream>
+</pkgmetadata>

dev-python/zope-testrunner/zope-testrunner-4.6.0.ebuild

@@ -0,0 +1,44 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} pypy{,3} )
+inherit distutils-r1
+
+MY_PN=${PN/-/.}
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Zope testrunner script"
+HOMEPAGE="https://pypi.python.org/pypi/zope.testrunner https://github.com/zopefoundation/zope.testrunner"
+SRC_URI="mirror://pypi/${MY_PN::1}/${MY_PN}/${MY_P}.zip"
+
+LICENSE="ZPL"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+# TODO: extras?
+RDEPEND="dev-python/namespace-zope[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	dev-python/zope-exceptions[${PYTHON_USEDEP}]
+	dev-python/zope-interface[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	app-arch/unzip
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? ( dev-python/zope-testing[${PYTHON_USEDEP}] )"
+
+S=${WORKDIR}/${MY_P}
+
+python_test() {
+	# some tests rely on .pyc files being present
+	local -x PYTHONDONTWRITEBYTECODE=
+	esetup.py test
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	# remove .pth files since dev-python/namespace-zope handles the ns
+	find "${D}" -name '*.pth' -delete || die
+}