From 497c2d0106e1f01004317ee4bb785156609e52dc Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Wed, 19 Apr 2023 08:05:00 +0200
Subject: [PATCH] dev-python/peewee: Bump to 3.16.1
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/peewee/Manifest             |  1 +
 dev-python/peewee/metadata.xml         |  6 +++
 dev-python/peewee/peewee-3.16.1.ebuild | 55 ++++++++++++++++++++++++++
 3 files changed, 62 insertions(+)
 create mode 100644 dev-python/peewee/peewee-3.16.1.ebuild

diff --git a/dev-python/peewee/Manifest b/dev-python/peewee/Manifest
index 8a20a15706cfb..46f1cfb03bd17 100644
--- a/dev-python/peewee/Manifest
+++ b/dev-python/peewee/Manifest
@@ -1 +1,2 @@
 DIST peewee-3.16.0.gh.tar.gz 1085430 BLAKE2B 3acfbbc9d8cce7e4bd1c0027905f4ca44431f376a243adffbfadd4d3f15b4e729c4736076e8ec72c40261ca269c66d811afb6c25b9d075d5913a13869da4f4dd SHA512 f77a040831bd3189135196ede9748c92af9db21127839dfacd7712586273bdd22c688ca22bfa373805fa1b64f770b7cea850cba53e73f324f25ced1305830409
+DIST peewee-3.16.1.gh.tar.gz 911668 BLAKE2B 6336d2edbf85b54dd98b3a67fc9507c626eee1d85293b12cf60d3a733d243d70a7df0583cd6024cb0550f8f31229702404692b0bf588e3c46e104ad64a095f37 SHA512 e89f1a2f25c2675403a560d3fa8eade833f9ef8b2fecfef00769a9633e99cb40feff7c4e1d2e9b001d4e6f50a8dae4594ffe22adfbe64a93035c47f673d5557c
diff --git a/dev-python/peewee/metadata.xml b/dev-python/peewee/metadata.xml
index 69c882d79303c..f2395542a7734 100644
--- a/dev-python/peewee/metadata.xml
+++ b/dev-python/peewee/metadata.xml
@@ -9,4 +9,10 @@
 		<remote-id type="github">coleifer/peewee</remote-id>
 		<remote-id type="pypi">peewee</remote-id>
 	</upstream>
+	<use>
+		<flag name="native-extensions">
+			Compiles native C extension for more complete SQLite3
+			support.
+		</flag>
+	</use>
 </pkgmetadata>
diff --git a/dev-python/peewee/peewee-3.16.1.ebuild b/dev-python/peewee/peewee-3.16.1.ebuild
new file mode 100644
index 0000000000000..5ad5f5f370428
--- /dev/null
+++ b/dev-python/peewee/peewee-3.16.1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{9..11} )
+PYTHON_REQ_USE="sqlite"
+
+inherit distutils-r1
+
+DESCRIPTION="Small Python ORM"
+HOMEPAGE="
+	https://github.com/coleifer/peewee/
+	https://pypi.org/project/peewee/
+"
+SRC_URI="
+	https://github.com/coleifer/${PN}/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv ~x86"
+IUSE="examples +native-extensions test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	native-extensions? ( dev-db/sqlite:3= )
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+"
+
+distutils_enable_sphinx docs
+
+src_compile() {
+	if ! use native-extensions; then
+		local -x NO_SQLITE=1
+	fi
+
+	distutils-r1_src_compile
+}
+
+python_test() {
+	"${EPYTHON}" runtests.py -v 2 || die "tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use examples && DOCS=( examples/ )
+	distutils-r1_python_install_all
+}