From 4974eb40edca49042ed1dba24d28469e6d18c180 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Mon, 28 Aug 2023 20:09:54 +0200
Subject: [PATCH] dev-python/tzdata: A shim package (v9999) to satisfy deps
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Add a shim package that installs metadata for `tzdata` to satisfy
the requirements of other packages while using system timezone-data.

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/tzdata/metadata.xml       |  8 +++++++
 dev-python/tzdata/tzdata-9999.ebuild | 34 ++++++++++++++++++++++++++++
 2 files changed, 42 insertions(+)
 create mode 100644 dev-python/tzdata/metadata.xml
 create mode 100644 dev-python/tzdata/tzdata-9999.ebuild

diff --git a/dev-python/tzdata/metadata.xml b/dev-python/tzdata/metadata.xml
new file mode 100644
index 0000000000000..7d421671d8846
--- /dev/null
+++ b/dev-python/tzdata/metadata.xml
@@ -0,0 +1,8 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+	</maintainer>
+	<stabilize-allarches/>
+</pkgmetadata>
diff --git a/dev-python/tzdata/tzdata-9999.ebuild b/dev-python/tzdata/tzdata-9999.ebuild
new file mode 100644
index 0000000000000..5e212ace5c26b
--- /dev/null
+++ b/dev-python/tzdata/tzdata-9999.ebuild
@@ -0,0 +1,34 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( pypy3 python3_{10..12} )
+
+inherit distutils-r1
+
+DESCRIPTION="tzdata shim to satisfy requirements (while using system tzdata)"
+HOMEPAGE="https://peps.python.org/pep-0615/"
+
+LICENSE="public-domain"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	sys-libs/timezone-data
+"
+
+src_unpack() {
+	mkdir "${S}" || die
+	cat > "${S}/pyproject.toml" <<-EOF || die
+		[build-system]
+		requires = ["hatchling"]
+		build-backend = "hatchling.build"
+
+		[project]
+		name = "tzdata"
+		version = "9999"
+		description = "tzdata shim to satisfy requirements (using system tzdata)"
+	EOF
+}