From 48da04c10274fc4273185ad29f90b3473ac7b5b3 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Petr=20Van=C4=9Bk?= <arkamar@gentoo.org>
Date: Mon, 21 Apr 2025 13:53:56 +0200
Subject: [PATCH] app-backup/borgbackup: add 1.4.1
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Petr Vaněk <arkamar@gentoo.org>
---
 app-backup/borgbackup/Manifest                |  1 +
 app-backup/borgbackup/borgbackup-1.4.1.ebuild | 69 +++++++++++++++++++
 2 files changed, 70 insertions(+)
 create mode 100644 app-backup/borgbackup/borgbackup-1.4.1.ebuild

diff --git a/app-backup/borgbackup/Manifest b/app-backup/borgbackup/Manifest
index 206bca49d5f80..30d76c08a7dfc 100644
--- a/app-backup/borgbackup/Manifest
+++ b/app-backup/borgbackup/Manifest
@@ -1 +1,2 @@
 DIST borgbackup-1.4.0.tar.gz 3798511 BLAKE2B 06d4d67e211a3ab1bc6d7155cbce8205fb7408a1149e44c77b500af02c25e62a569e3eaf50c11916a2ff9adea47c5791febfb7d0c657d0b195e5c5bbbd33a7d7 SHA512 f5866ece2d153d1e43127a04fd288a09403a9ea2ae4c981cb9ff855bd303b53c133c006f0b1a77541edc4f64940431e9c4d49ec45a3646784a29fe3b8828237a
+DIST borgbackup-1.4.1.tar.gz 3817197 BLAKE2B fbf5cd06bcddd5b90db75ed1b2276d2eba0d17d0545a751acfd40d051053d9d3e1a0ea2f1dd87e6541aeca6199e98ad1885b9d3155696268752069b763b660a4 SHA512 83ce8fcefa4e4099922e1f3894aba41d8d83ccff3e554b4b5ee0f0b9b8b18b18bcbf7f566e36aea4214e0d9d427cb66d63d2e1933b773e3338fd5814fd80e3a4
diff --git a/app-backup/borgbackup/borgbackup-1.4.1.ebuild b/app-backup/borgbackup/borgbackup-1.4.1.ebuild
new file mode 100644
index 0000000000000..7282efe613cc9
--- /dev/null
+++ b/app-backup/borgbackup/borgbackup-1.4.1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit bash-completion-r1 distutils-r1 pypi
+
+DESCRIPTION="Deduplicating backup program with compression and authenticated encryption"
+HOMEPAGE="https://borgbackup.readthedocs.io/"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+
+DEPEND="
+	app-arch/lz4
+	app-arch/zstd
+	dev-libs/openssl:0=
+	>=dev-libs/xxhash-0.8.1
+	virtual/acl
+"
+# borgbackup is *very* picky about which msgpack it work with,
+# check setup.py on bumps.
+RDEPEND="
+	${DEPEND}
+	<=dev-python/msgpack-1.1.0[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/pyfuse3[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	dev-python/pkgconfig[${PYTHON_USEDEP}]
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/python-dateutil[${PYTHON_USEDEP}]
+	)
+"
+
+# some tests randomly fail with xdist, bug #936524
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Needs pytest-benchmark fixture
+		benchmark.py::test_
+	)
+
+	# This disables fuse releated tests
+	local -x BORG_FUSE_IMPL="none"
+	epytest --pyargs borg.testsuite
+}
+
+src_install() {
+	distutils-r1_src_install
+	doman docs/man/*
+
+	dobashcomp scripts/shell_completions/bash/borg
+
+	insinto /usr/share/zsh/site-functions
+	doins scripts/shell_completions/zsh/_borg
+
+	insinto /usr/share/fish/vendor_completions.d
+	doins scripts/shell_completions/fish/borg.fish
+}