diff --git a/dev-python/tifffile/Manifest b/dev-python/tifffile/Manifest
index 439cbf051296f..334a1cacab931 100644
--- a/dev-python/tifffile/Manifest
+++ b/dev-python/tifffile/Manifest
@@ -1 +1,2 @@
 DIST tifffile-2026.8.23.gh.tar.gz 428025 BLAKE2B b6021be6bc47814a09847f610dd1f111317830df31aacaf3d68a793933c5bcfbd625f4607c7ac9c68907db295f8c17148d2b6215d6ef809215863b09ca1a4497 SHA512 86778792b8f156798dba02a3288bc7cff4fd09e1a7feef57104469761699a1c0bf76bebc08fe9e8620c2a368617189cb2dcd5273b1a06bef767629d42f6e4bff
+DIST tifffile-2026.9.9.gh.tar.gz 427709 BLAKE2B 8e935e91b9bc43ec74ed26f0d7b1038b3c2ea9e03cd90b6712d3fc2999fe584954b1baa5111baa1ec00e4ca4e556adde3ee9092ae7031ffd00c690aec06bbc5d SHA512 75256c187bf979d55217b945e1443e2d3d895821c200b96f72a9ba98e4f3c84e879f776e8c7b30e0cefceb6d0ab8770c67d8abc31da8db633f8726b2be53f4d9
diff --git a/dev-python/tifffile/tifffile-2026.9.9.ebuild b/dev-python/tifffile/tifffile-2026.9.9.ebuild
new file mode 100644
index 0000000000000..637e43979e1e8
--- /dev/null
+++ b/dev-python/tifffile/tifffile-2026.9.9.ebuild
@@ -0,0 +1,56 @@
+# Copyright 2021-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{12..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="Read and write TIFF files"
+HOMEPAGE="
+	https://pypi.org/project/tifffile/
+	https://github.com/cgohlke/tifffile/
+	https://www.cgohlke.com/
+"
+SRC_URI="
+	https://github.com/cgohlke/tifffile/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/numpy-2.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/defusedxml[${PYTHON_USEDEP}]
+		>=dev-python/fsspec-2021.5.0[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+		dev-python/xarray[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# not marked properly
+		# https://github.com/cgohlke/tifffile/pull/308
+		tests/test_tifffile.py::test_issue_dcp
+		# meaningless and broken on py<3.13
+		# https://github.com/cgohlke/tifffile/pull/309
+		tests/test_tifffile.py::test_gil_enabled
+	)
+
+	local -x SKIP_LARGE=1
+	local -x SKIP_HTTP=1
+
+	epytest
+}