diff --git a/gnustep-libs/sope/Manifest b/gnustep-libs/sope/Manifest
index b9fa0890b43ca..d4690b3777318 100644
--- a/gnustep-libs/sope/Manifest
+++ b/gnustep-libs/sope/Manifest
@@ -1 +1,2 @@
 DIST sope-5.12.7.tar.gz 2228334 BLAKE2B 67ae6464de6d95fbb321ca9eb613bde0f40b2e88138a69d22f566bf681a2c0660a3be3000a757df95820df3c5d84745d3f6b291c2bd0fb4fc23cab5c5d90f429 SHA512 23d284eca9c5f559b3b9bdfe91a4800b76a1115027650c509d2765114d29cb89079792f478254a80f8d7d4656c382ef31008ebb05bc5cfa972b4f709155fde6c
+DIST sope-5.12.8.tar.gz 2228314 BLAKE2B e7dccc8a79858dce50f6568dc53038356a03a235a52c627c98d4af371d1d23d2519ba3e6fc8dbc172dcd889af2f5f2537aaba7550ac7fd6a550ac7b266a4f670 SHA512 b5615544223ed6725fa01f08a9cb159784f29f94b0b1f4499ebb144825e7cde9d538e4e500b3c2aa812dd383b8d590ed2128e41fd5e5eb61c260918dc3dd0dda
diff --git a/gnustep-libs/sope/sope-5.12.8.ebuild b/gnustep-libs/sope/sope-5.12.8.ebuild
new file mode 100644
index 0000000000000..8a6358bdf01ab
--- /dev/null
+++ b/gnustep-libs/sope/sope-5.12.8.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnustep-2
+
+DESCRIPTION="A set of frameworks forming a complete Web application server environment"
+HOMEPAGE="https://www.sogo.nu/"
+SRC_URI="https://github.com/inverse-inc/sope/archive/SOPE-${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-${PN^^}-${PV}"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gnutls ldap mysql postgres +ssl +xml"
+
+RDEPEND="
+	virtual/zlib:=
+	ldap? ( net-nds/openldap:= )
+	gnutls? ( net-libs/gnutls:= )
+	!gnutls? (
+		dev-libs/openssl:0=
+	)
+	mysql? ( dev-db/mysql-connector-c:= )
+	postgres? ( dev-db/postgresql:= )
+	xml? ( dev-libs/libxml2:2= )
+"
+DEPEND="${RDEPEND}"
+
+src_configure() {
+	egnustep_env
+
+	local myconf=(
+		--prefix="${EPREFIX}"
+		--disable-strip
+		$(use_enable debug)
+		$(use_enable ldap openldap)
+		$(use_enable mysql)
+		$(use_enable postgres postgresql)
+		$(use_enable xml)
+		--with-gnustep
+	)
+
+	if use ssl ; then
+		if use gnutls ; then
+			myconf+=( --with-ssl=gnutls )
+		else
+			myconf+=( --with-ssl=ssl )
+		fi
+	else
+		myconf+=( --with-ssl=none )
+	fi
+
+	# Non-standard configure script
+	./configure "${myconf[@]}" || die "configure failed"
+}