dev-python/dulwich: 0.18.6

Package-Manager: Portage-2.3.19, Repoman-2.3.6

dev-python/dulwich/Manifest

@@ -1 +1,2 @@
 DIST dulwich-0.18.5.tar.gz 330097 BLAKE2B c29f3016ab63082051c8c4fc42301c12ca752008a317afc41defceee2db47e50efb69b9a21b3d50c241b3b51c32222c1e9cf35eedaf2811f66cec2330ce7865a SHA512 4ba0f70ebddf4c7f4e71721812e228f820226d4ea42bda4d5f06a0720a029d4dddb800cfc05b2610525922c5fcef1020edd1485105706d9ef3fcf810e6381035
+DIST dulwich-0.18.6.tar.gz 331325 BLAKE2B 781227bf91d8df8f941dd2eddb1682fb8c358d37f35671b08334ef197355e33dbbd09d18b43a179f9200cd6abca563a2fc833da68bd860859a52d951fe679ac0 SHA512 2d2120e23dd4bc2c9dcfe601f21ac757ee3fe2a343923c50b32c067f4d329ac89cdf0894bff450bf52c69e99759bb8692f0f14ed73d01be6bc3b0402d58d1148

dev-python/dulwich/dulwich-0.18.6.ebuild

@@ -0,0 +1,50 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+
+inherit distutils-r1
+
+DESCRIPTION="Pure-Python implementation of the Git file formats and protocols"
+HOMEPAGE="https://github.com/jelmer/dulwich/ https://pypi.python.org/pypi/dulwich"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="doc examples test"
+
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/gevent[${PYTHON_USEDEP}]
+		dev-python/geventhttpclient[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/python-fastimport[${PYTHON_USEDEP}]
+	)"
+
+DISTUTILS_IN_SOURCE_BUILD=1
+
+# One test sometimes fails
+# https://github.com/jelmer/dulwich/issues/541
+PATCHES=( "${FILESDIR}/${PN}-0.18.3-skip-failing-test.patch" )
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	emake check
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/build/html/. )
+	if use examples; then
+		insinto "/usr/share/doc/${PF}"
+		docompress -x "/usr/share/doc/${PF}/examples"
+		doins -r examples
+	fi
+	distutils-r1_python_install_all
+}