dev-python/ginga:

Package-Manager: Portage-2.3.6, Repoman-2.3.3

dev-python/ginga/Manifest

@@ -1,2 +1,3 @@
 DIST ginga-2.6.2.tar.gz 17258711 SHA256 a8bc2fd66f1a74b56282ce53086446a9aa2d9a0628911669615c3e0f7e3d5526 SHA512 be9f24382019fb0d1c2013cf8da00518234da787ce54a724dccae273e093fd843e8b6a0ea206d288123835328c26961e71a59a48b179cd7d2898e02148e4f62a WHIRLPOOL 453f1d834d1c99a0a873e749f0507a56af0007d0e0783d80a95c25ceb13e6f2d85ba2b64eb3e10680ebb308ad5d2c4ea6871605eeacf2c4d5880f29a18695fae
 DIST ginga-2.6.4.tar.gz 19971195 SHA256 25d3435af454135c3539108ab41d4a55169e939739e0a947f12643dce16aa16e SHA512 79c471ee3fefb6dc03c90538147b8fa8606b37b7747712f9a69163870e6ae460d259f0ea08388a07163ea8b588676d0208fcdd51577d04cfc334aacbd0c01599 WHIRLPOOL 7ab2c47015446aae322f5a167a4054f40e601f2d0ace9b164a87bf4cf1f084765d7cc05592a69847010fee20b780e47a4532defcd5acfbdf6ba74568dd6dbc52
+DIST ginga-2.6.5.tar.gz 19969984 SHA256 0a8000a2e872d10fd05368cf3fa9d48d67c9191877998d764cd681f3f88b0e25 SHA512 66c55662a8ce1fe683cdf6a83511f39146fadf10d1fedabd6d6c5c46662a3abd2496bd1f0200612a84bdad246f960990e242bccee7a8a13e3aaf88a4884ceb80 WHIRLPOOL 76284b1ada78ff60bfb7e350f71ed1d6e81f73704757574864a64fb437d80fd1ab011fa50daadd231dae75dc3d22efb76d48f14678538e7949a7f56a6f44412e

dev-python/ginga/ginga-2.6.5.ebuild

@@ -0,0 +1,77 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_5,3_6} )
+PYTHON_REQ_USE='tk?'
+
+inherit distutils-r1 eutils fdo-mime virtualx
+
+DESCRIPTION="Astronomical image toolkit for Python"
+HOMEPAGE="https://ejeschke.github.io/ginga"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="examples gtk qt4 qt5 test tk"
+
+RDEPEND="
+	dev-python/astropy[${PYTHON_USEDEP}]
+	media-fonts/roboto
+	gtk? (  dev-python/pygobject[${PYTHON_USEDEP},cairo] )
+	qt4? ( || (
+		   dev-python/pyside[${PYTHON_USEDEP},help,X]
+		   dev-python/PyQt4[${PYTHON_USEDEP},help,X]
+		  )
+		  dev-python/QtPy[${PYTHON_USEDEP},gui]
+	   )
+	qt5? (
+		 dev-python/PyQt5[${PYTHON_USEDEP},help,gui,widgets]
+		 dev-python/QtPy[${PYTHON_USEDEP},gui]
+	)
+"
+
+DEPEND="${RDEPEND}
+	dev-python/astropy-helpers[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? ( dev-python/QtPy[${PYTHON_USEDEP},gui] )
+"
+
+PATCHES=( "${FILESDIR}"/${PN}-no-roboto.patch )
+
+python_prepare_all() {
+	# use system astropy-helpers instead of bundled one
+	sed -i -e '/auto_use/s/True/False/' setup.cfg || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	virtx esetup.py test
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	rm -r "${ED%/}"/usr/lib*/*/*/ginga/examples || die
+	if use examples; then
+		dodoc -r ginga/examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+	domenu ginga.desktop
+}
+
+pkg_postinst() {
+	optfeature "Pick, Cuts, Histogram, LineProfile" \
+			   dev-python/matplotlib sci-libs/scipy
+	optfeature "Online help browser" dev-qt/qtwebkit
+	optfeature "To save a movie" media-video/mplayer
+	optfeature "Speeds up rotation and some transformations" \
+			   dev-python/numexpr dev-python/opencv dev-python/pyopencl
+	optfeature "Aids in identifying files when opening them" \
+			   dev-python/filemagic
+	optfeature "Useful for various RGB file manipulations" dev-python/pillow
+
+	# Update mimedb for the new .desktop file
+	fdo-mime_desktop_database_update
+}