dev-python/dnspython: Conver to py ABI slotted ebuilds

Gentoo-Bug: https://bugs.gentoo.org/show_bug.cgi?id=484954

Package-Manager: portage-2.2.23
Signed-off-by: Justin Lecher <jlec@gentoo.org>

dev-python/dnspython/dnspython-1.12.0-r200.ebuild

@@ -0,0 +1,38 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit distutils-r1
+
+DESCRIPTION="DNS toolkit for Python"
+HOMEPAGE="http://www.dnspython.org/ https://pypi.python.org/pypi/dnspython"
+SRC_URI="http://www.dnspython.org/kits/${PV}/${P}.tar.gz"
+
+LICENSE="ISC"
+SLOT="py2"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-solaris"
+IUSE="examples test"
+
+RDEPEND="dev-python/pycrypto[${PYTHON_USEDEP}]
+	!dev-python/dnspython:0"
+DEPEND="${RDEPEND}
+	!dev-python/dnspython:0
+	app-arch/unzip"
+
+# For testsuite
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_test() {
+	cd tests || die
+	"${PYTHON}" utest.py || die "tests failed under ${EPYTHON}"
+	einfo "Testsuite passed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use examples && local EXAMPLES=( examples/. )
+	distutils-r1_python_install_all
+}