dev-util/nsight-systems: add 2025.3.1

Signed-off-by: David Seifert <soap@gentoo.org>

dev-util/nsight-systems/Manifest

@@ -1,2 +1,4 @@
 DIST nsight-systems-2025.2.1_2025.2.1.130-1_amd64.deb 428406244 BLAKE2B d7831f8adbef228d9ca7308b5466dfacc064560885980e59e5d6d25df64a6cc901bb9c58ffbe2734a9c57fd249f6809d52b7a8f3ed10516a398d8cbdc4b2d214 SHA512 74d407e12f560ff2fdb8c09d91733fa78bea8470ba181253ad9946f1e770a5f5e7a15c6d27e41d133e6d670b83e527b1fd7249d1d066f7dfecd17962371e4ea3
 DIST nsight-systems-2025.2.1_2025.2.1.130-1_arm64.deb 401367200 BLAKE2B 714bff59f4779cf5b86e002bf6cd6fca24ac5f5b9cd5a5626499cd78c88e6b4ad70445869c2045b9d31e3c2c36efe253f49f9843548a75744ba074cd863e4681 SHA512 881d2f9278206187297936c875b75344302268a32514149a2e246cc7eb0c68cbcd1cc1e8dee44a305abafd8cfabe90875e296ef99450db1a58336499945b775e
+DIST nsight-systems-2025.3.1_2025.3.1.90-1_amd64.deb 429429534 BLAKE2B e50025ac05ce13682493d137b04b99d1d21fe786f69d6806aa05347dd7459a570564955222e4bef1d47885a9b035e1b92c7aef8fb27bac9bac6b001da10bb3f0 SHA512 88c95b2568d89512a8ec996aa361e56af7c2aa5a3b01ee439aed3ea8b96a7cb5823b91845aa03dfcab3147d17a725a92da7e1c81e819473da18c264607728afa
+DIST nsight-systems-2025.3.1_2025.3.1.90-1_arm64.deb 402311178 BLAKE2B a3199ba0ea0786725177e505398feb932d75517007bb44de65d0ab0ad6598d2a46261dabf0948b647a984619adb5e8140fe196fb4ebbb47b5b1ae1f4be381e03 SHA512 2e4f0572b755699d4a47825e0811ea4d96b563d443d9142dda46364596d937cc46bc140a37f005f828797982767126f2dcaee658971d002df1f0cb58e402c5b5

dev-util/nsight-systems/nsight-systems-2025.3.1.ebuild

@@ -0,0 +1,118 @@
+# Copyright 2024-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit edo unpacker
+
+DESCRIPTION="performance analysis tool designed to visualize an application's algorithms"
+HOMEPAGE="https://developer.nvidia.com/nsight-systems"
+
+MY_PV="$(ver_rs 1-2 '_' "$(ver_cut 1-2)")"
+MY_PN="${PN//nsight-}"
+MY_PN_SHORT="sys"
+PV_BUILD="90-1"
+
+SRC_URI="
+	amd64? (
+		https://developer.nvidia.com/downloads/assets/tools/secure/${PN}/${MY_PV}/${PN}-${PV}_${PV}.${PV_BUILD}_amd64.deb
+	)
+	arm64? (
+		https://developer.nvidia.com/downloads/assets/tools/secure/${PN}/${MY_PV}/${PN}-${PV}_${PV}.${PV_BUILD}_arm64.deb
+	)
+"
+
+S="${WORKDIR}"
+
+LICENSE="NVIDIA-r2"
+SLOT="${PV}"
+KEYWORDS="~amd64 ~arm64"
+
+RESTRICT="bindist mirror strip test"
+
+RDEPEND="
+	app-crypt/mit-krb5
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	dev-libs/wayland
+	dev-qt/qtwayland:6
+	media-libs/fontconfig
+	media-libs/freetype
+	media-libs/gst-plugins-base:1.0
+	media-libs/gstreamer:1.0
+	media-libs/libglvnd
+	media-libs/tiff-compat:4
+	sys-apps/dbus
+	sys-cluster/rdma-core
+	x11-drivers/nvidia-drivers
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/libXrender
+	x11-libs/libXtst
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/libxkbfile
+	x11-libs/libxshmfence
+	x11-libs/xcb-util-image
+	x11-libs/xcb-util-keysyms
+	x11-libs/xcb-util-renderutil
+	x11-libs/xcb-util-wm
+	arm64? (
+		media-libs/gst-plugins-bad:1.0
+	)
+"
+BDEPEND="
+	dev-util/patchelf
+"
+
+QA_PREBUILT="/opt/nvidia/${PN}/$(ver_cut 1-2)"
+
+src_prepare() {
+	if use amd64; then
+		sed \
+			-e "/Terminal/s/=No/=false/" \
+			-e "/Categories/s/Application;//" \
+			-i usr/share/applications/*.desktop || die
+
+		if [[ -n "${EPREFIX}" ]]; then
+			sed  -e "s#=/#=${EPREFIX}/#g" -i usr/share/applications/*.desktop || die
+		fi
+	fi
+
+	local rpaths rpath
+	readarray -t rpaths < <(
+		find "${S}/opt/nvidia/${PN}/${PV}/host-linux-"* \
+			-name 'libparquet*.so*.0.0' -o \
+			-name 'libarrow*.so*.0.0' -o \
+			-name 'libssh.so'|| die
+	)
+	for rpath in "${rpaths[@]}"; do
+		edob -m "fixing rpath for ${rpath}" \
+			patchelf --set-rpath '$ORIGIN' "${rpath}"
+	done
+
+	eapply_user
+}
+
+src_configure() {
+	:
+}
+
+src_compile() {
+	:
+}
+
+src_install() {
+	rm -r usr/local || die
+	mv ./* "${ED}" || die
+
+	# TODO install desktop file for arm64
+}