From 43a07d3e3e77b4b262a444eb9b367086dbe245aa Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Fri, 10 Apr 2026 20:22:58 +0200
Subject: [PATCH] dev-python/nox: Bump to 2026.04.10
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/nox/Manifest              |  1 +
 dev-python/nox/nox-2026.04.10.ebuild | 65 ++++++++++++++++++++++++++++
 2 files changed, 66 insertions(+)
 create mode 100644 dev-python/nox/nox-2026.04.10.ebuild

diff --git a/dev-python/nox/Manifest b/dev-python/nox/Manifest
index 57ae9a6743934..663eb76cc8ab5 100644
--- a/dev-python/nox/Manifest
+++ b/dev-python/nox/Manifest
@@ -1 +1,2 @@
 DIST nox-2026.02.09.gh.tar.gz 4031394 BLAKE2B 6d2c04dec43c09ef2163c04f73ea0833c1963abae7c13a96d6f526e2f936b976d19e4fe79e5272d7b86bed920e9cb362c60fae655a07296d7b509c959096a8e0 SHA512 3ae5901f7f001e5cc607e99d8360697343dd8c7717f2f5b55937b2a759617d0493b37779672cefa0f18153529f46945b10db6a8352e222b0508bc683fc6fbd3f
+DIST nox-2026.04.10.gh.tar.gz 4035107 BLAKE2B c714b751e689643ef340a08e1d004cde2775180688be683bd699dc2ed950809c322cb33c4891bc0e3b3b2c87cb51139f6ac07038763eedfdd0e17342fc805edd SHA512 4771fcb8df3a43a2aa3c4a01d4bb377d1f5720b234e147c062c5bbe539173da67823318a821c89f754e8eff1206ea84c43d32006438c98131e9eda766567b1ba
diff --git a/dev-python/nox/nox-2026.04.10.ebuild b/dev-python/nox/nox-2026.04.10.ebuild
new file mode 100644
index 0000000000000..77e53945eddd6
--- /dev/null
+++ b/dev-python/nox/nox-2026.04.10.ebuild
@@ -0,0 +1,65 @@
+# Copyright 2023-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( pypy3_11 python3_{11..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="Flexible test automation for Python"
+HOMEPAGE="
+	https://github.com/wntrblm/nox/
+	https://pypi.org/project/nox/
+"
+SRC_URI="
+	https://github.com/wntrblm/nox/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+RDEPEND="
+	>=dev-python/argcomplete-1.9.4[${PYTHON_USEDEP}]
+	>=dev-python/attrs-24.1[${PYTHON_USEDEP}]
+	>=dev-python/colorlog-2.6.1[${PYTHON_USEDEP}]
+	>=dev-python/dependency-groups-1.1[${PYTHON_USEDEP}]
+	>=dev-python/humanize-4[${PYTHON_USEDEP}]
+	>=dev-python/packaging-22[${PYTHON_USEDEP}]
+	>=dev-python/virtualenv-20.15[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/pbs-installer-2025.01.06[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO: conda?
+		'tests/test_sessions.py::TestSessionRunner::test__create_venv_options[nox.virtualenv.CondaEnv.create-conda-CondaEnv]'
+		# Internet
+		tests/test_virtualenv.py::test_uv_install
+		tests/test_main.py::test_noxfile_script_mode
+	)
+
+	case ${EPYTHON} in
+		pypy3*)
+			EPYTEST_DESELECT+=(
+				# hardcoded CPython assumption
+				tests/test_tox_to_nox.py::test_commands_with_requirements
+				tests/test_tox_to_nox.py::test_skipinstall
+				tests/test_tox_to_nox.py::test_trivial
+				tests/test_tox_to_nox.py::test_usedevelop
+			)
+			;;
+	esac
+
+	epytest -o tmp_path_retention_policy=all
+}