dev-python/pyro: Version Bump

Package-Manager: portage-2.2.23
Signed-off-by: Justin Lecher <jlec@gentoo.org>

dev-python/pyro/Manifest

@@ -1,3 +1,4 @@
 DIST Pyro-3.16.tar.gz 298769 SHA256 1bed508453ef7a7556b51424a58101af2349b662baab7e7331c5cb85dbe7e578 SHA512 d0e4ae93120a6566a2b06fa52b66e20daa972324a9d57d639ca68171e1e6e5c412250f7e6af3fc307631d2270be3731ea5898ad35819dc0369e6a2d8341d5965 WHIRLPOOL 0d7efcead6bc7a31a690c012a4213c835d43ca932e461ab25ddb2e12636970de2c3da6feb4915385bdadaf2261558d2041d5e6dad9899f11e450aa0a065460da
 DIST Pyro4-4.25.tar.gz 295993 SHA256 ac2b0123badcb76c63eb716fcd95e0ee4021d345b5db05fda19253c59e39b384 SHA512 9a112e679a304d250549701d9a1baef0df6d3ea6f1eec559e7c433eab7ab09155c9ae440817f844be073f69dc8bf93836d48930b1d91311eaf6ab7e91c0a4faf WHIRLPOOL aa767569948af1cf222b95fa114d4dee08b601296f8be1ed9bce86502f1c9eeedf05930215da192ab9d237d740283f88a5f7efe1f53291acd1b90b51099a1801
 DIST Pyro4-4.39.tar.gz 496566 SHA256 39c6ca7f86b0f0bebfeada687a5a8b99f66470a52b0f815195ae63c683266f24 SHA512 ac303401abe997b7ce0914a804538dcee9195bbe3fe1d07cf18be0592cbb4dbd161413e8d7a696a8dc1e29ff64fe98877ea1fa9811d9961340441cf414f31d98 WHIRLPOOL fc4377552f9e5f5666671d909b7c071095933625baea891535c976f735dab8f3d1b5b3f0132be2fcf9a003024d874a88ddd092b127127c0376807a1d2894d393
+DIST Pyro4-4.40.tar.gz 501340 SHA256 00423d3710f60b2da146075a59e17bfa837f556ed2c8acafe05bc209dcaac3e9 SHA512 43ee1b0dd3e700d9fed16c5fceda30074dc6cd3cbd466efe911711eb81f1c4bce1967bed06225922e45812e04e36c49cd42d24c0edca1845159d1035326896e7 WHIRLPOOL fdc5f2f405a217db0840218201b1d943ef5828513cc606135dbe5dd7fb723dedec78ad25e8ea6cc2ca0a3e4b374eb8a73fe7db0dae6dcac117c0af9d0e757def

dev-python/pyro/pyro-4.40.ebuild

@@ -0,0 +1,78 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 python3_{3,4,5} pypy )
+
+inherit distutils-r1
+
+MY_PN="Pyro4"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Advanced and powerful Distributed Object Technology system written entirely in Python"
+HOMEPAGE="http://www.xs4all.nl/~irmen/pyro/ https://pypi.python.org/pypi/Pyro4 https://github.com/irmen/Pyro4"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="4"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc examples test"
+
+RDEPEND="
+	!dev-python/pyro:0
+	>=dev-python/serpent-1.11[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/coverage[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+	)"
+
+S="${WORKDIR}/${MY_P}"
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_prepare_all() {
+	sed \
+		-e '/sys.path.insert/a sys.path.insert(1,"PyroTests")' \
+		-i tests/run_testsuite.py || die
+
+	# Disable tests requiring network connection.
+	sed \
+		-e "s/testBCstart/_&/" \
+		-e "s/testDaemonPyroObj/_&/" \
+		-e "s/testLookupAndRegister/_&/" \
+		-e "s/testMulti/_&/" \
+		-e "s/testRefuseDottedNames/_&/" \
+		-e "s/testResolve/_&/" \
+		-e "s/testBCLookup/_&/" \
+		-i tests/PyroTests/test_naming.py || die
+	sed \
+		-e "s/testOwnloopBasics/_&/" \
+		-e "s/testStartNSfunc/_&/" \
+		-i tests/PyroTests/test_naming2.py || die
+
+	sed \
+		-e "s/testServerConnections/_&/" \
+	    -e "s/testServerParallelism/_&/" \
+		-i tests/PyroTests/test_server.py || die
+
+	sed \
+		-e "s/testBroadcast/_&/" \
+		-e "s/testGetIP/_&/" \
+		-e "s/testGetIpVersion[46]/_&/" \
+		-i tests/PyroTests/test_socket.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	cd "${S}"/tests || die
+	${PYTHON} -E run_testsuite.py || die
+}
+
+python_install_all() {
+	use doc && HTML_DOCS=( docs/. )
+	use examples && local EXAMPLES=( examples/. )
+	distutils-r1_python_install_all
+}